1 files changed, 43 insertions, 0 deletions
diff --git a/dev-python/pymediainfo/pymediainfo-2.1.9.ebuild b/dev-python/pymediainfo/pymediainfo-2.1.9.ebuild
new file mode 100644
index 000000000000..6846d34175cf
--- /dev/null
+++ b/dev-python/pymediainfo/pymediainfo-2.1.9.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_{4,5,6}} )
+
+inherit distutils-r1
+
+DESCRIPTION="A wrapper around the mediainfo library"
+HOMEPAGE="https://github.com/sbraz/pymediainfo"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="media-libs/libmediainfo"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		${RDEPEND}
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-runner[${PYTHON_USEDEP}]
+	)
+"
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_test() {
+	# requires network access
+	py.test tests/test.py -k "not MediaInfoURLTest" \
+		|| die "tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}