1 files changed, 46 insertions, 0 deletions
diff --git a/dev-python/pysnmp/pysnmp-4.4.12-r1.ebuild b/dev-python/pysnmp/pysnmp-4.4.12-r1.ebuild
new file mode 100644
index 000000000000..4464b7b64c02
--- /dev/null
+++ b/dev-python/pysnmp/pysnmp-4.4.12-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit distutils-r1
+
+DESCRIPTION="Python SNMP library"
+HOMEPAGE="http://snmplabs.com/pysnmp/ https://pypi.org/project/pysnmp/ https://github.com/etingof/pysnmp"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~ia64 ppc ~sparc x86"
+IUSE="doc examples"
+
+RDEPEND="
+	>=dev-python/pyasn1-0.2.3[${PYTHON_USEDEP}]
+	dev-python/pysmi[${PYTHON_USEDEP}]
+	dev-python/pycryptodome[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs/source
+
+python_prepare_all() {
+	touch docs/source/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	if use examples; then
+		docinto examples
+		dodoc -r examples/. docs/mibs
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	elog "You may also be interested in the following packages: "
+	elog "dev-python/pysnmp-apps - example programs using pysnmp"
+	elog "dev-python/pysnmp-mibs - IETF and other mibs"
+	elog "dev-python/pysmi - to dump MIBs in python format"
+}