1 files changed, 49 insertions, 0 deletions
diff --git a/dev-python/python-dateutil/python-dateutil-2.7.3.ebuild b/dev-python/python-dateutil/python-dateutil-2.7.3.ebuild
new file mode 100644
index 000000000000..cc406d817e01
--- /dev/null
+++ b/dev-python/python-dateutil/python-dateutil-2.7.3.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6,7} pypy pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Extensions to the standard Python datetime module"
+HOMEPAGE="
+	https://dateutil.readthedocs.org/
+	https://pypi.org/project/python-dateutil
+	https://github.com/dateutil/dateutil/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="test"
+
+RDEPEND="
+	>=dev-python/six-1.5[${PYTHON_USEDEP}]
+	sys-libs/timezone-data
+"
+DEPEND="${RDEPEND}
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/freezegun[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	local PATCHES=(
+		"${FILESDIR}"/0001-zoneinfo-Get-timezone-data-from-system-tzdata.patch
+	)
+
+	# don't install zoneinfo tarball
+	sed -i '/package_data=/d' setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	py.test -v || die "Tests failed under ${EPYTHON}"
+}