summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'dev-python/pyx')
-rw-r--r--dev-python/pyx/Manifest1
-rw-r--r--dev-python/pyx/pyx-0.15_p1.ebuild90
2 files changed, 91 insertions, 0 deletions
diff --git a/dev-python/pyx/Manifest b/dev-python/pyx/Manifest
index 7103b8d91882..175aaacac94d 100644
--- a/dev-python/pyx/Manifest
+++ b/dev-python/pyx/Manifest
@@ -1,2 +1,3 @@
DIST W3C_SVG_11_TestSuite.tar.gz 14651624 BLAKE2B 680059d8b20775725cebb3aed4444acbc3222fde880ba93ee5186c99fc12afa8df2c790bdacbcd6e5ff4ab00e697d8317a9a6ae3039b8b2f02cf7774a18ca533 SHA512 e28e3996284c3f3e423e2b6957cddea71980bcb781d4180894e08f37a7ecce9c6021917329d6d433dcba792cbabb15c7cd503076e616ba5189193a5c554374ca
DIST pyx-0.15.gh.tar.gz 875286 BLAKE2B 49d36e1c0df3ee47a895279d7f296194324cf1582bb7db0259bcd01c9b17c4d0903c25fef10c7a22635fac62dc6378ffbece200eac99f75bb3ce81d48a71a0d1 SHA512 a7debff01f8055455855f4cac5a08d00c22d20d7918bd7341d2af83844223ae8bb23bbbe92149403656e18ffb8861e8568dfdcb59cc01c55ec60e63b62a8825a
+DIST pyx-0.15_p1.tar.bz2 746171 BLAKE2B 5b2325c7bb279e4f6425f0ba7f3808b7e540c7455738c617efdf1ad9d383a466d1b67b90e20e0bdbfa7d2fc56f1c80a4ae2badc5ef78f63ec410370d516f4ab3 SHA512 97809a38029011735d2cdea8f7e8326890d748d4159f44379f89c396b7ea4d2a026ca3370bb069974b07215da91a47b9334d8dd1f7db954c2dd272122bde8ff0
diff --git a/dev-python/pyx/pyx-0.15_p1.ebuild b/dev-python/pyx/pyx-0.15_p1.ebuild
new file mode 100644
index 000000000000..0d9517439908
--- /dev/null
+++ b/dev-python/pyx/pyx-0.15_p1.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+#DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python package for the generation of encapsulated PostScript figures"
+HOMEPAGE="
+ https://github.com/pyx-project/pyx
+ https://pyx-project.org/
+ https://pypi.org/project/PyX/"
+# git 0f28343
+SRC_URI="https://dev.gentoo.org/~grozin/${P}.tar.bz2
+ test? ( https://www.w3.org/Graphics/SVG/Test/20110816/archives/W3C_SVG_11_TestSuite.tar.gz )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ dev-python/pillow[${PYTHON_USEDEP}]
+ virtual/tex-base
+ dev-texlive/texlive-basic"
+
+BDEPEND="${RDEPEND}
+ doc? (
+ virtual/latex-base
+ $(python_gen_any_dep '
+ dev-python/sphinx[latex,${PYTHON_USEDEP}]
+ dev-python/sphinx_selective_exclude[${PYTHON_USEDEP}]
+ ')
+ )
+ test? (
+ dev-python/sphinx[${PYTHON_USEDEP}]
+ dev-python/sphinx_selective_exclude[${PYTHON_USEDEP}]
+ dev-python/testfixtures[${PYTHON_USEDEP}]
+ )"
+
+PATCHES=( "${FILESDIR}"/pyx-0.14.1-unicode-latex.patch )
+
+python_check_deps() {
+ use doc || return 0
+ has_version "dev-python/sphinx[latex,${PYTHON_USEDEP}]" &&
+ has_version "dev-python/sphinx_selective_exclude[${PYTHON_USEDEP}]"
+}
+
+src_unpack() {
+ unpack "${P}.tar.bz2"
+
+ if use test; then
+ mkdir "${S}"/test/svg/suite || die
+ cd "${S}"/test/svg/suite || die
+ unpack W3C_SVG_11_TestSuite.tar.gz
+ fi
+}
+
+src_prepare() {
+ sed -i \
+ -e 's/^build_t1code=.*/build_t1code=1/' \
+ -e 's/^build_pykpathsea=.*/build_pykpathsea=1/' \
+ setup.cfg || die "setup.cfg fix failed"
+ # stop test suite from downloading files
+ sed -i \
+ -e '/suite:/,$d' test/svg/Makefile || die
+ distutils-r1_src_prepare
+}
+
+python_compile_all() {
+ if use doc; then
+ local -x VARTEXFONTS="${T}"/fonts
+ emake -C "${S}"/manual latexpdf
+ emake -C "${S}"/faq latexpdf
+ fi
+}
+
+python_test() {
+ emake -C test
+}
+
+python_install_all() {
+ use doc && dodoc manual/_build/latex/manual.pdf faq/_build/latex/pyxfaq.pdf
+ distutils-r1_python_install_all
+}