1 files changed, 41 insertions, 0 deletions
diff --git a/dev-python/pyxDamerauLevenshtein/pyxDamerauLevenshtein-1.8.0.ebuild b/dev-python/pyxDamerauLevenshtein/pyxDamerauLevenshtein-1.8.0.ebuild
new file mode 100644
index 000000000000..ba5134da1eae
--- /dev/null
+++ b/dev-python/pyxDamerauLevenshtein/pyxDamerauLevenshtein-1.8.0.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Implements the Damerau-Levenshtein edit distance algorithm for Python in Cython"
+HOMEPAGE="
+	https://github.com/lanl/pyxDamerauLevenshtein/
+	https://pypi.org/project/pyxDamerauLevenshtein/
+"
+SRC_URI="
+	https://github.com/lanl/pyxDamerauLevenshtein/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~riscv ~x86"
+
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_configure() {
+	# recythonize
+	cd pyxdameraulevenshtein || die
+	cython -3 -f *.pyx || die
+}
+
+src_test() {
+	rm -r pyxdameraulevenshtein || die
+	distutils-r1_src_test
+}