1 files changed, 45 insertions, 0 deletions
diff --git a/dev-python/sphinxcontrib-spelling/sphinxcontrib-spelling-7.3.0.ebuild b/dev-python/sphinxcontrib-spelling/sphinxcontrib-spelling-7.3.0.ebuild
new file mode 100644
index 000000000000..1bbda9a87600
--- /dev/null
+++ b/dev-python/sphinxcontrib-spelling/sphinxcontrib-spelling-7.3.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1
+
+DESCRIPTION="Sphinx spelling extension"
+HOMEPAGE="https://github.com/sphinx-contrib/spelling"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	dev-python/pyenchant[${PYTHON_USEDEP}]
+	dev-python/sphinx[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/pbr[${PYTHON_USEDEP}]
+	test? (
+		app-dicts/myspell-en
+	)
+"
+
+# The doc can only be built from a git repository
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	tests/test_filter.py::test_contributors
+)
+
+# We don't want distutils_enable_tests to add the namespace
+# package to BDEPEND under "test?". Therefore we add it to RDEPEND
+# after running distutils_enable_tests.
+RDEPEND+="
+	dev-python/namespace-sphinxcontrib[${PYTHON_USEDEP}]
+"
+
+python_install_all() {
+	distutils-r1_python_install_all
+	find "${ED}" -name '*.pth' -delete || die
+}