1 files changed, 0 insertions, 96 deletions
diff --git a/dev-python/subunit/subunit-1.4.2.ebuild b/dev-python/subunit/subunit-1.4.2.ebuild
deleted file mode 100644
index aeffed44ac22..000000000000
--- a/dev-python/subunit/subunit-1.4.2.ebuild
+++ /dev/null
@@ -1,96 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{9..11} pypy3 )
-
-inherit distutils-r1 multilib-minimal autotools
-
-DESCRIPTION="A streaming protocol for test results"
-HOMEPAGE="
-	https://launchpad.net/subunit/
-	https://pypi.org/project/python-subunit/
-"
-SRC_URI="
-	https://github.com/testing-cabal/subunit/archive/${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-
-LICENSE="Apache-2.0 BSD"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86"
-IUSE="static-libs test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	>=dev-python/testtools-0.9.34[${PYTHON_USEDEP}]
-	dev-python/extras[${PYTHON_USEDEP}]
-	dev-lang/perl:=
-"
-DEPEND="
-	${RDEPEND}
-	>=dev-libs/check-0.9.11[${MULTILIB_USEDEP}]
-	>=dev-util/cppunit-1.13.2[${MULTILIB_USEDEP}]
-	>=virtual/pkgconfig-0-r1
-	test? (
-		dev-python/fixtures[${PYTHON_USEDEP}]
-		dev-python/hypothesis[${PYTHON_USEDEP}]
-		dev-python/testscenarios[${PYTHON_USEDEP}]
-	)
-"
-
-PATCHES=(
-	"${FILESDIR}/subunit-1.4.0-werror.patch"
-)
-
-src_prepare() {
-	# Install perl modules in vendor_perl, bug 534654.
-	export PERL_INSTALLDIRS=vendor
-
-	mv all_tests.py python/ || die
-
-	distutils-r1_src_prepare
-	eautoreconf
-	multilib_copy_sources
-}
-
-multilib_src_configure() {
-	ECONF_SOURCE=${S} \
-	econf \
-		--enable-shared \
-		$(use_enable static-libs static)
-}
-
-multilib_src_compile() {
-	default
-	multilib_is_native_abi && distutils-r1_src_compile
-}
-
-python_test() {
-	cd python || die
-	"${EPYTHON}" -m testtools.run -v all_tests.test_suite ||
-		die "Testing failed with ${EPYTHON}"
-}
-
-multilib_src_test() {
-	multilib_is_native_abi && distutils-r1_src_test
-}
-
-multilib_src_install() {
-	local targets=(
-		install-include_subunitHEADERS
-		install-pcdataDATA
-		install-exec-local
-		install-libLTLIBRARIES
-	)
-	emake DESTDIR="${D}" "${targets[@]}"
-
-	multilib_is_native_abi && distutils-r1_src_install
-}
-
-multilib_src_install_all() {
-	einstalldocs
-	find "${D}" -name '*.la' -delete || die
-}