1 files changed, 50 insertions, 0 deletions
diff --git a/dev-python/waitress/waitress-0.8.10.ebuild b/dev-python/waitress/waitress-0.8.10.ebuild
new file mode 100644
index 000000000000..c9fe158908cb
--- /dev/null
+++ b/dev-python/waitress/waitress-0.8.10.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="A pure-Python WSGI server"
+HOMEPAGE="http://docs.pylonsproject.org/projects/waitress/en/latest/ https://pypi.python.org/pypi/waitress/ https://github.com/Pylons/waitress"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz \
+		doc? ( https://dev.gentoo.org/~idella4/pylons_sphinx_theme.tar.gz )"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="doc test"
+
+RDEPEND=""
+DEPEND="${RDEPEND}
+	app-arch/unzip
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	if use doc; then
+		local PATCHES=( "${FILESDIR}"/${P}-doc.patch )
+		mv "${WORKDIR}"/_themes ./docs/ || die
+	fi
+
+	# Fix generation of documentation with Waitress not installed. Bug #525384
+	sed -e "s/^version = pkg_resources.get_distribution('waitress').version$/version = '${PV}'/" -i docs/conf.py
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	nosetests || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}