1 files changed, 42 insertions, 0 deletions
diff --git a/dev-python/werkzeug/werkzeug-2.0.1.ebuild b/dev-python/werkzeug/werkzeug-2.0.1.ebuild
new file mode 100644
index 000000000000..d9a91a7036a5
--- /dev/null
+++ b/dev-python/werkzeug/werkzeug-2.0.1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Collection of various utilities for WSGI applications"
+HOMEPAGE="
+	https://werkzeug.palletsprojects.com/
+	https://pypi.org/project/Werkzeug/
+	https://github.com/pallets/werkzeug"
+SRC_URI="
+	https://github.com/pallets/werkzeug/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~x86"
+
+DEPEND="
+	test? (
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		!hppa? ( !ia64? (
+			$(python_gen_cond_dep '
+				dev-python/greenlet[${PYTHON_USEDEP}]
+			' 'python*')
+		) )
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/pytest-xprocess[${PYTHON_USEDEP}]
+		dev-python/watchdog[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+python_test() {
+	# the default portage tempdir is too long for AF_UNIX sockets
+	local -x TMPDIR=/tmp
+	epytest -p no:httpbin tests
+}