2 files changed, 67 insertions, 0 deletions
diff --git a/dev-python/pyopenssl/Manifest b/dev-python/pyopenssl/Manifest
index 89b1a679a5ac..0adf713b5f32 100644
--- a/dev-python/pyopenssl/Manifest
+++ b/dev-python/pyopenssl/Manifest
@@ -1 +1,2 @@
 DIST pyOpenSSL-23.1.1.tar.gz 183402 BLAKE2B c0339203bb1794da67a0c2fe2e20b5736b3e0628d01b13805e3c30771d60fe07df22a7c090260cf1fad80abb1e566e2efd1e8e184a142e335189fa3bd885e7ac SHA512 581f907ac9acf71c3340bbd413ecf161dafeac1cb406649c683fc770f8bcfcc1630a977defa9b3ee218631959ed14ea62d0a02cdf74af9fdce5ddec34ad1e1ea
+DIST pyOpenSSL-23.2.0.tar.gz 185132 BLAKE2B 06330623bf5934b89cf88dee508c2c4bdd170f805a111f082624b2f8c59fd56e48d5954ef7d9f98768e88aaabaa9e04594ea717784a86401e6e64433e699c9b8 SHA512 a467801bf94959a067d9d3551b47d17d4798bf0b87d253d41a89cac9cdb1731a967a98bda3e83ab8a560ed5fdc0a17f34604f3c6e0f6789bc4c920bc49f520c9
diff --git a/dev-python/pyopenssl/pyopenssl-23.2.0.ebuild b/dev-python/pyopenssl/pyopenssl-23.2.0.ebuild
new file mode 100644
index 000000000000..80d9faec3657
--- /dev/null
+++ b/dev-python/pyopenssl/pyopenssl-23.2.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+PYPI_NO_NORMALIZE=1
+PYPI_PN=pyOpenSSL
+
+inherit distutils-r1 toolchain-funcs pypi
+
+DESCRIPTION="Python interface to the OpenSSL library"
+HOMEPAGE="
+	https://www.pyopenssl.org/
+	https://github.com/pyca/pyopenssl/
+	https://pypi.org/project/pyOpenSSL/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	<dev-python/cryptography-42[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-40.0.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/cffi[${PYTHON_USEDEP}]
+		' 'python*')
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/pretend[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx doc \
+	dev-python/sphinx-rtd-theme
+distutils_enable_tests pytest
+
+src_test() {
+	local -x TZ=UTC
+	local EPYTEST_DESELECT=(
+		tests/test_ssl.py::TestContext::test_set_default_verify_paths
+	)
+
+	# test for 32-bit time_t
+	"$(tc-getCC)" ${CFLAGS} ${CPPFLAGS} -c -x c - -o /dev/null <<-EOF &>/dev/null
+		#include <sys/types.h>
+		int test[sizeof(time_t) >= 8 ? 1 : -1];
+	EOF
+
+	if [[ ${?} -eq 0 ]]; then
+		einfo "time_t is at least 64-bit long"
+	else
+		einfo "time_t is smaller than 64 bits, will skip broken tests"
+		EPYTEST_DESELECT+=(
+			tests/test_crypto.py::TestX509StoreContext::test_verify_with_time
+		)
+	fi
+
+	distutils-r1_src_test
+}