1 files changed, 57 insertions, 0 deletions
diff --git a/dev-qt/designer/designer-5.14.2.ebuild b/dev-qt/designer/designer-5.14.2.ebuild
new file mode 100644
index 000000000000..8e394f7f3b59
--- /dev/null
+++ b/dev-qt/designer/designer-5.14.2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+QT5_MODULE="qttools"
+inherit desktop qt5-build xdg-utils
+
+DESCRIPTION="WYSIWYG tool for designing and building graphical user interfaces with QtWidgets"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86"
+fi
+
+IUSE="declarative webkit"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}:5=
+	~dev-qt/qtgui-${PV}:5=
+	~dev-qt/qtnetwork-${PV}
+	~dev-qt/qtprintsupport-${PV}
+	~dev-qt/qtwidgets-${PV}
+	~dev-qt/qtxml-${PV}
+	declarative? ( ~dev-qt/qtdeclarative-${PV}[widgets] )
+	webkit? ( >=dev-qt/qtwebkit-5.9.1:5 )
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/designer
+)
+
+src_prepare() {
+	qt_use_disable_mod declarative quickwidgets \
+		src/designer/src/plugins/plugins.pro
+
+	qt_use_disable_mod webkit webkitwidgets \
+		src/designer/src/plugins/plugins.pro
+
+	qt5-build_src_prepare
+}
+
+src_install() {
+	qt5-build_src_install
+
+	doicon -s 128 src/designer/src/designer/images/designer.png
+	make_desktop_entry "${QT5_BINDIR}"/designer 'Qt 5 Designer' designer 'Qt;Development;GUIDesigner'
+}
+
+pkg_postinst() {
+	qt5-build_pkg_postinst
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	qt5-build_pkg_postrm
+	xdg_icon_cache_update
+}