1 files changed, 37 insertions, 0 deletions
diff --git a/dev-qt/linguist-tools/linguist-tools-5.15.2-r10.ebuild b/dev-qt/linguist-tools/linguist-tools-5.15.2-r10.ebuild
new file mode 100644
index 000000000000..d9508fdf3bab
--- /dev/null
+++ b/dev-qt/linguist-tools/linguist-tools-5.15.2-r10.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KDE_ORG_COMMIT=33693a928986006d79c1ee743733cde5966ac402
+QT5_MODULE="qttools"
+inherit qt5-build
+
+DESCRIPTION="Tools for working with Qt translation data files"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+IUSE="qml"
+
+DEPEND="
+	=dev-qt/qtcore-${QT5_PV}*:5=
+	=dev-qt/qtxml-${QT5_PV}*
+	qml? ( =dev-qt/qtdeclarative-${QT5_PV}* )
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/linguist
+)
+
+src_prepare() {
+	sed -i -e '/SUBDIRS += linguist/d' \
+		src/linguist/linguist.pro || die
+
+	qt_use_disable_mod qml qmldevtools-private \
+		src/linguist/lupdate/lupdate.pro
+
+	qt5-build_src_prepare
+}