1 files changed, 48 insertions, 0 deletions
diff --git a/dev-ruby/capistrano/capistrano-2.15.5-r3.ebuild b/dev-ruby/capistrano/capistrano-2.15.5-r3.ebuild
new file mode 100644
index 000000000000..6beebd2f0210
--- /dev/null
+++ b/dev-ruby/capistrano/capistrano-2.15.5-r3.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+USE_RUBY="ruby25 ruby26 ruby27"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG README.md"
+
+RUBY_FAKEGEM_BINWRAP=""
+
+inherit ruby-fakegem
+
+DESCRIPTION="A distributed application deployment system"
+HOMEPAGE="https://capistranorb.com/"
+
+LICENSE="MIT"
+SLOT="2"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-solaris ~x86-solaris"
+IUSE=""
+
+ruby_add_rdepend "
+	>=dev-ruby/net-ssh-2.0.14:*
+	>=dev-ruby/net-sftp-2.0.2
+	>=dev-ruby/net-scp-1.0.2
+	>=dev-ruby/net-ssh-gateway-1.1.0:*
+	>=dev-ruby/highline-1.2.7"
+ruby_add_bdepend "
+	test? (	dev-ruby/mocha:0.14 )"
+
+PATCHES=( "${FILESDIR}/${P}-sudo-cleanup.patch" )
+
+all_ruby_prepare() {
+	rm Gemfile || die
+	sed -i -e '/[Bb]undler/d' Rakefile test/utils.rb || die
+	sed -i -e '/pry/ s:^:#:' -e '4igem "mocha", "~>0.14.0"' test/utils.rb || die
+
+	# Avoid copy strategy tests since these fail in some cases due to
+	# complicated (aka unknown) interactions with other parts of the
+	# test suite.
+	rm test/deploy/strategy/copy_test.rb || die
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	ruby_fakegem_binwrapper cap /usr/bin/cap-2 'gem "capistrano", "~>2.0"'
+}