1 files changed, 50 insertions, 0 deletions
diff --git a/dev-ruby/maxitest/maxitest-5.4.0.ebuild b/dev-ruby/maxitest/maxitest-5.4.0.ebuild
new file mode 100644
index 000000000000..737952209473
--- /dev/null
+++ b/dev-ruby/maxitest/maxitest-5.4.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby31 ruby32"
+
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
+
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Minitest + all the features you always wanted"
+HOMEPAGE="https://github.com/grosser/maxitest"
+SRC_URI="https://github.com/grosser/maxitest/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="1"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE=""
+
+ruby_add_rdepend ">=dev-ruby/minitest-5.14.0:* <dev-ruby/minitest-5.21.0:*"
+
+ruby_add_bdepend "test? ( dev-ruby/bundler )"
+
+all_ruby_prepare() {
+	rm -f Gemfile.lock || die
+	# Remove developer-only gems from the gemspec and avoid git issues
+	sed -e 's:_relative ": "./:' \
+		-i ${RUBY_FAKEGEM_GEMSPEC} || die
+	sed -i -e '/\(debug\|bump\)/ s:^:#:' Gemfile || die
+
+	sed -e '/shows backtrace for/askip' \
+		-e '/describe.*line/ s/describe/xdescribe/' \
+		-e '/describe.*color/ s/describe/xdescribe/' \
+		-i spec/maxitest_spec.rb || die
+}
+
+each_ruby_prepare() {
+	# Use the correct target
+	sed -e '/\(run_cmd\|sh\)/ s:ruby:'${RUBY}':' \
+		-e '/\(run_cmd\|sh\)/ s:mtest:'${RUBY}' -S bin/mtest:' \
+		-i spec/maxitest_spec.rb || die
+}
+
+each_ruby_test() {
+	PATH="${S}/bin:${PATH}" RUBYLIB="${S}/lib" RSPEC_VERSION=3 ruby-ng_rspec spec
+}