1 files changed, 42 insertions, 0 deletions
diff --git a/dev-ruby/timecop/timecop-0.9.7.ebuild b/dev-ruby/timecop/timecop-0.9.7.ebuild
new file mode 100644
index 000000000000..08c2499661a4
--- /dev/null
+++ b/dev-ruby/timecop/timecop-0.9.7.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby30 ruby31 ruby32"
+
+RUBY_FAKEGEM_BINWRAP=""
+RUBY_FAKEGEM_TASK_TEST="test"
+
+RUBY_FAKEGEM_TASK_DOC="rdoc"
+RUBY_FAKEGEM_DOCDIR="rdoc"
+RUBY_FAKEGEM_EXTRADOC="README.markdown"
+RUBY_FAKEGEM_GEMSPEC="timecop.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A gem providing 'time travel' and 'time freezing' capabilities"
+HOMEPAGE="https://github.com/travisjeffery/timecop"
+SRC_URI="https://github.com/travisjeffery/timecop/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE=""
+
+# Missing testdep activesupport
+ruby_add_bdepend "test? ( dev-ruby/mocha )"
+
+all_ruby_prepare() {
+	sed -i -e '/bundler/ s:^:#:' -e '/History.rdoc/d' Rakefile test/test_helper.rb || die
+	sed -i -e '/rubygems/ a\gem "test-unit"' \
+		-e '/minitest\/rg/ s:^:#:' -e '/pry/ s:^:#:' test/test_helper.rb || die
+	# FIXME after activesupport gained ruby22 support
+	rm test/time_stack_item_test.rb || die
+}
+
+each_ruby_test() {
+	for f in test/*_test.rb ; do
+		${RUBY} -Ilib $f || die
+	done
+}