1 files changed, 61 insertions, 0 deletions
diff --git a/dev-ruby/twitter/twitter-5.17.0-r1.ebuild b/dev-ruby/twitter/twitter-5.17.0-r1.ebuild
new file mode 100644
index 000000000000..19a8ee195cf5
--- /dev/null
+++ b/dev-ruby/twitter/twitter-5.17.0-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+USE_RUBY="ruby20 ruby21 ruby22"
+
+RUBY_FAKEGEM_RECIPE_DOC="yard"
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
+
+RUBY_FAKEGEM_GEMSPEC="twitter.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Ruby wrapper around the Twitter API"
+HOMEPAGE="https://sferik.github.com/twitter/"
+SRC_URI="https://github.com/sferik/twitter/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="5"
+KEYWORDS="~amd64"
+IUSE=""
+
+ruby_add_rdepend "
+	>=dev-ruby/addressable-2.3
+	>=dev-ruby/buftok-0.2.0
+	>=dev-ruby/equalizer-0.0.10
+	=dev-ruby/faraday-0*
+	>=dev-ruby/faraday-0.9.0
+	dev-ruby/http:1.0
+	>=dev-ruby/http_parser_rb-0.6.0
+	>=dev-ruby/json-1.8:0
+	>=dev-ruby/memoizable-0.4.0
+	>=dev-ruby/naught-1.0
+	=dev-ruby/simple_oauth-0.3*
+	>=dev-ruby/simple_oauth-0.3.0"
+
+ruby_add_bdepend "test? (
+	dev-ruby/rspec:3
+	dev-ruby/webmock:0
+	>=dev-ruby/timecop-0.6.1
+	)
+	doc? ( dev-ruby/yard )"
+
+all_ruby_prepare() {
+	sed -i -e '/equalizer/ s/0.0.10/~>0.0.10/' \
+		-e '/faraday/ s/0.9.0/0.9/' ${RUBY_FAKEGEM_GEMSPEC} || die
+
+#	rm Gemfile || die
+	sed -i -e '/[Bb]undler/d' Rakefile || die "Unable to remove bundler code."
+
+	sed -i -e '/simplecov/,/^  end/ s:^:#:' \
+		-e '1igem "webmock", "~>1.0"' spec/helper.rb || die
+
+	# Avoid a spec that fails due to changes in dependencies.
+	sed -i -e '/#reverse_token/,/^  end/ s:^:#:' \
+		spec/twitter/rest/oauth_spec.rb
+}
+
+each_ruby_test() {
+	CI=true RSPEC_VERSION=3 ruby-ng_rspec || die
+}