2 files changed, 96 insertions, 0 deletions
diff --git a/dev-scheme/gambit/Manifest b/dev-scheme/gambit/Manifest
index 53e8c13c3b6a..a2368302bed5 100644
--- a/dev-scheme/gambit/Manifest
+++ b/dev-scheme/gambit/Manifest
@@ -1 +1,2 @@
 DIST gambit-4.9.4.tar.gz 15453486 BLAKE2B 59761f98fe380604b7b5d8be162769506536aaffb35e97c24a755b3cd62e2e72e830468add0ca098e87fba3d1716363b9125b0141dea4eee5608fa55abcbe2cf SHA512 f2963e5e33ad5cc773924cd1ac01bdf6ad68ba6514419583c4a94c0c878ae223c06c9a90b9058cec9c2237f905b6e3cd879360b04415473199a1a515ae4194ee
+DIST gambit-4.9.5.tar.gz 15859590 BLAKE2B d1b835928ce81259abc9fb2872fb7a521387cd3a8ceccd919a844d9c6543ab0796ab83c4f0ee5aac1c64ea4af0fb8310ba959214de6ff8f2e6e9ea683ab218c9 SHA512 7211f0734197b2ae84ded88efda3dd622c75ce76de6f4e299e54cb08b8e199e886f7ea778867eb7d2e358be660edf2fd0ae01d0fc5be9875176e84813c5fd702
diff --git a/dev-scheme/gambit/gambit-4.9.5.ebuild b/dev-scheme/gambit/gambit-4.9.5.ebuild
new file mode 100644
index 000000000000..e5ab7d8bab84
--- /dev/null
+++ b/dev-scheme/gambit/gambit-4.9.5.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic elisp-common
+
+DESCRIPTION="Gambit-C is a native Scheme to C compiler and interpreter"
+HOMEPAGE="http://www.iro.umontreal.ca/~gambit/
+	https://github.com/gambit/gambit/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
+else
+	SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}-tags-v${PV}"
+
+	KEYWORDS="~amd64 ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="|| ( Apache-2.0 LGPL-2.1 )"
+SLOT="0"
+IUSE="emacs ssl static"
+
+RDEPEND="
+	ssl? ( dev-libs/openssl:0= )
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	app-text/ghostscript-gpl
+	emacs? ( >=app-editors/emacs-23.1:* )
+"
+
+DOCS=( INSTALL.txt README README.md )
+SITEFILE="50${PN}-gentoo.el"
+
+src_configure() {
+	# bug #858254
+	filter-lto
+
+	local -a myconf=(
+		$(use_enable !static shared)
+		$(use_enable ssl openssl)
+		--enable-gnu-gcc-specific-options
+		--enable-gnu-gcc-no-strict-aliasing
+		--enable-single-host
+		--disable-absolute-shared-libs
+		--enable-type-checking
+	)
+	econf "${myconf[@]}"
+}
+
+src_compile() {
+	emake bootstrap
+
+	if use emacs ; then
+		elisp-compile misc/*.el
+	fi
+}
+
+src_test() {
+	cd tests || die
+
+	emake test{1..10}
+}
+
+src_install() {
+	emake DESTDIR="${ED}" install -j1
+
+	if use emacs ; then
+		elisp-install "${PN}" misc/*.el{,c}
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	fi
+
+	dodoc doc/gambit.{pdf,ps,txt}
+	einstalldocs
+
+	# Wrong install directory for this ELisp library.
+	rm "${ED}/usr/share/emacs/site-lisp/gambit.el" || die
+
+	keepdir "/usr/share/${PN}"
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}