1 files changed, 37 insertions, 0 deletions
diff --git a/dev-util/checkbashisms/checkbashisms-2.20.5.ebuild b/dev-util/checkbashisms/checkbashisms-2.20.5.ebuild
new file mode 100644
index 000000000000..1d567b48dc59
--- /dev/null
+++ b/dev-util/checkbashisms/checkbashisms-2.20.5.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN="devscripts"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Perl script to check for commonly used bash features not defined by POSIX"
+HOMEPAGE="https://packages.debian.org/devscripts https://salsa.debian.org/debian/devscripts"
+SRC_URI="mirror://debian/pool/main/d/${MY_PN}/${MY_P/-/_}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+# Requires python packages to check tools we don't need anyway
+RESTRICT="test"
+
+RDEPEND="dev-lang/perl
+	virtual/perl-Getopt-Long"
+
+S="${WORKDIR}/${MY_P}/scripts"
+
+src_prepare() {
+	default
+
+	sed "s@###VERSION###@${PV}@" -i checkbashisms.pl || die
+}
+
+src_compile() { :; }
+
+src_install() {
+	newbin ${PN}.pl ${PN}
+	doman ${PN}.1
+}