1 files changed, 0 insertions, 95 deletions
diff --git a/dev-util/pkgconfig/pkgconfig-0.28-r2.ebuild b/dev-util/pkgconfig/pkgconfig-0.28-r2.ebuild
deleted file mode 100644
index b6eb4fb04312..000000000000
--- a/dev-util/pkgconfig/pkgconfig-0.28-r2.ebuild
+++ /dev/null
@@ -1,95 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=5
-
-inherit epatch flag-o-matic libtool multilib multilib-minimal
-
-MY_P=pkg-config-${PV}
-
-if [[ ${PV} == *9999* ]]; then
-	EGIT_REPO_URI="https://anongit.freedesktop.org/git/pkg-config.git"
-	inherit autotools git-2
-else
-	KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~m68k ~mips ppc ppc64 ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
-	SRC_URI="https://pkgconfig.freedesktop.org/releases/${MY_P}.tar.gz"
-fi
-
-DESCRIPTION="Package config system that manages compile/link flags"
-HOMEPAGE="https://pkgconfig.freedesktop.org/wiki/"
-
-LICENSE="GPL-2"
-SLOT="0"
-IUSE="elibc_FreeBSD elibc_glibc hardened internal-glib"
-
-RDEPEND="!internal-glib? ( >=dev-libs/glib-2.34.3[${MULTILIB_USEDEP}] )
-	!dev-util/pkgconf[pkg-config]
-	!dev-util/pkg-config-lite
-	!dev-util/pkgconfig-openbsd[pkg-config]"
-DEPEND="${RDEPEND}"
-
-S=${WORKDIR}/${MY_P}
-
-DOCS=( AUTHORS NEWS README )
-
-src_prepare() {
-	epatch "${FILESDIR}"/${P}-strip_system_library_dirs_reliably.patch
-
-	sed -i -e "s|^prefix=/usr\$|prefix=${EPREFIX}/usr|" check/simple.pc || die #434320
-
-	epatch_user
-
-	if [[ ${PV} == *9999* ]]; then
-		eautoreconf
-	else
-		elibtoolize
-	fi
-}
-
-multilib_src_configure() {
-	local myconf
-
-	if use internal-glib; then
-		myconf+=' --with-internal-glib'
-		# non-glibc platforms use GNU libiconv, but configure needs to
-		# know about that not to get confused when it finds something
-		# outside the prefix too
-		if use prefix && use !elibc_glibc ; then
-			myconf+=" --with-libiconv=gnu"
-			# add the libdir for libtool, otherwise it'll make love with system
-			# installed libiconv
-			append-ldflags "-L${EPREFIX}/usr/$(get_libdir)"
-		fi
-	else
-		if ! has_version --host-root dev-util/pkgconfig; then
-			export GLIB_CFLAGS="-I${EPREFIX}/usr/include/glib-2.0 -I${EPREFIX}/usr/$(get_libdir)/glib-2.0/include"
-			export GLIB_LIBS="-lglib-2.0"
-		fi
-	fi
-
-	use ppc64 && use hardened && replace-flags -O[2-3] -O1
-
-	# Force using all the requirements when linking, so that needed -pthread
-	# lines are inherited between libraries
-	use elibc_FreeBSD && myconf+=' --enable-indirect-deps'
-
-	[[ ${PV} == *9999* ]] && myconf+=' --enable-maintainer-mode'
-
-	ECONF_SOURCE=${S} \
-	econf \
-		--docdir="${EPREFIX}"/usr/share/doc/${PF}/html \
-		--with-system-include-path="${EPREFIX}"/usr/include \
-		--with-system-library-path="${EPREFIX}"/usr/$(get_libdir) \
-		${myconf}
-}
-
-multilib_src_install() {
-	emake DESTDIR="${D}" install
-
-	if use prefix; then
-		# Add an explicit reference to $EPREFIX to PKG_CONFIG_PATH to
-		# simplify cross-prefix builds
-		echo "PKG_CONFIG_PATH=${EPREFIX}/usr/$(get_libdir)/pkgconfig:${EPREFIX}/usr/share/pkgconfig" >> "${T}"/99${PN}
-		doenvd "${T}"/99${PN}
-	fi
-}