1 files changed, 58 insertions, 0 deletions
diff --git a/games-action/bzflag/bzflag-2.4.4-r1.ebuild b/games-action/bzflag/bzflag-2.4.4-r1.ebuild
new file mode 100644
index 000000000000..8e98ce4fbd83
--- /dev/null
+++ b/games-action/bzflag/bzflag-2.4.4-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit eutils flag-o-matic
+
+DESCRIPTION="3D tank combat simulator game"
+HOMEPAGE="http://www.bzflag.org/"
+SRC_URI="https://download.bzflag.org/bzflag/source/${PV}/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="dedicated upnp"
+
+DEPEND="
+	net-dns/c-ares
+	>=net-misc/curl-7.15.0
+	sys-libs/ncurses:0
+	sys-libs/zlib
+	!dedicated? (
+		media-libs/libsdl[joystick,sound,video]
+		virtual/glu
+		virtual/opengl )
+	upnp? ( net-libs/miniupnpc )"
+RDEPEND=${DEPEND}
+
+PATCHES=(
+	"${FILESDIR}"/${P}-configure.patch
+)
+
+src_configure() {
+	local myconf
+
+	if use dedicated ; then
+		ewarn
+		ewarn "You are building a server-only copy of BZFlag"
+		ewarn
+		myconf="--disable-client --without-SDL"
+	fi
+
+	econf \
+		$(use_enable upnp UPnP) \
+		${myconf}
+}
+
+src_install() {
+	DOCS="AUTHORS ChangeLog DEVINFO PORTING README README.Linux" \
+		default
+
+	if ! use dedicated ; then
+		newicon data/bzflag-48x48.png ${PN}.png
+		make_desktop_entry ${PN} "BZFlag"
+	fi
+
+	prune_libtool_files --modules
+}