1 files changed, 37 insertions, 0 deletions
diff --git a/games-arcade/cosmosmash/cosmosmash-1.4.8.ebuild b/games-arcade/cosmosmash/cosmosmash-1.4.8.ebuild
new file mode 100644
index 000000000000..7ca6cd6f8ad0
--- /dev/null
+++ b/games-arcade/cosmosmash/cosmosmash-1.4.8.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools
+
+DESCRIPTION="A space rock shooting video game"
+HOMEPAGE="https://perso.b2b2c.ca/~sarrazip/dev/cosmosmash.html"
+SRC_URI="http://perso.b2b2c.ca/~sarrazip/dev/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+RESTRICT="test" # uses the sound card which portage user might not be available.
+
+RDEPEND=">=dev-games/flatzebra-0.1.7"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	sed -i \
+		-e "/^pkgsounddir/ s:sounds.*:\$(PACKAGE)/sounds:" \
+		-e "/^desktopentrydir/ s:=.*:=/usr/share/applications:" \
+		-e "/^pixmapdir/ s:=.*:=/usr/share/pixmaps:" \
+		src/Makefile.am \
+		|| die
+	eautoreconf
+}
+
+src_install() {
+	emake -C src DESTDIR="${D}" install
+	einstalldocs
+	doman doc/${PN}.6
+}