1 files changed, 64 insertions, 0 deletions
diff --git a/games-board/cockatrice/cockatrice-20200823.ebuild b/games-board/cockatrice/cockatrice-20200823.ebuild
new file mode 100644
index 000000000000..fa3bd9ba82ed
--- /dev/null
+++ b/games-board/cockatrice/cockatrice-20200823.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit xdg cmake
+
+MY_PV="2020-08-23-Release-2.7.5"
+DESCRIPTION="An open-source multiplatform software for playing card games over a network"
+HOMEPAGE="https://github.com/Cockatrice/Cockatrice"
+SRC_URI="https://github.com/Cockatrice/Cockatrice/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+client +oracle test server"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtprintsupport:5
+	dev-qt/qtwebsockets:5
+	dev-qt/qtwidgets:5
+	client? (
+		dev-libs/protobuf:=
+		dev-qt/qtmultimedia:5
+		dev-qt/qtsvg:5
+	)
+	oracle? ( sys-libs/zlib )
+	server? (
+		dev-libs/protobuf:=
+		dev-qt/qtsql:5
+	)
+"
+BDEPEND="
+	dev-qt/linguist-tools:5
+	client? ( dev-libs/protobuf )
+	server? ( dev-libs/protobuf )
+	test? ( dev-cpp/gtest )
+"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/Cockatrice-${MY_PV}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_SHARED_LIBS=OFF
+		-DUSE_CCACHE=OFF
+		-DWITH_CLIENT=$(usex client)
+		-DWITH_ORACLE=$(usex oracle)
+		-DWITH_SERVER=$(usex server)
+		-DTEST=$(usex test)
+		-DICONDIR="${EPREFIX}/usr/share/icons"
+		-DDESKTOPDIR="${EPREFIX}/usr/share/applications" )
+
+	# Add date in the help about, come from git originally
+	sed -e 's/^set(PROJECT_VERSION_FRIENDLY.*/set(PROJECT_VERSION_FRIENDLY \"'${MY_PV}'\")/' \
+		-i cmake/getversion.cmake || die "sed failed!"
+
+	cmake_src_configure
+}