1 files changed, 60 insertions, 0 deletions
diff --git a/games-emulation/gnuboy/gnuboy-1.0.3-r3.ebuild b/games-emulation/gnuboy/gnuboy-1.0.3-r3.ebuild
new file mode 100644
index 000000000000..9fd915b37c0a
--- /dev/null
+++ b/games-emulation/gnuboy/gnuboy-1.0.3-r3.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Gameboy emulator with multiple renderers"
+HOMEPAGE="https://sourceforge.net/projects/gnuboy/"
+SRC_URI="mirror://gentoo/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+sdl X"
+REQUIRED_USE="!X? ( sdl )"
+
+RDEPEND="
+	sdl? ( media-libs/libsdl )
+	X? ( x11-libs/libXext )
+"
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-exec-stack.patch
+	"${FILESDIR}"/${P}-linux-headers.patch
+	"${FILESDIR}"/${P}-include.patch
+	"${FILESDIR}"/${P}-fix-implicit-decl-sprintf.patch
+)
+
+src_prepare() {
+	default
+
+	mv configure.in configure.ac || die
+	eautoreconf
+}
+
+src_configure() {
+	local myconf
+
+	econf \
+		$(use_with X x) \
+		$(use_with sdl) \
+		$(use_enable x86 asm) \
+		${myconf} \
+		--disable-arch \
+		--disable-optimize
+}
+
+src_install() {
+	for f in sdlgnuboy xgnuboy; do
+		if [[ -f ${f} ]] ; then
+			dobin ${f}
+		fi
+	done
+
+	dodoc README docs/{CHANGES,CONFIG,CREDITS,FAQ,HACKING,WHATSNEW}
+}