2 files changed, 0 insertions, 99 deletions
diff --git a/games-emulation/hatari/Manifest b/games-emulation/hatari/Manifest
index c2b7a9379001..e5dec1b910f2 100644
--- a/games-emulation/hatari/Manifest
+++ b/games-emulation/hatari/Manifest
@@ -1,2 +1 @@
-DIST hatari-2.4.0.tar.bz2 4452205 BLAKE2B fe53b4dac688720372386fc83a83996e2cc83d74fd20f71db5e60f773561dc51d33f3560c1625913a896a9592650460604e821c9f7f07e5bd50d1775b49dfea5 SHA512 8ec542b2f7e27cd185ff8725e8d31ba7f1de709fa638b6162d17b6f1163158cbd16fc2738aa6b073a71cd990a72f305b5322f754faef34399cdca8685a7bf08c
 DIST hatari-2.4.1.tar.bz2 4446656 BLAKE2B 0844f14f2161de931ba098d290655152ecde354a80cc9c18b460fda77149759386cf7ed46d0ce1dd36dc303f1f3cfe421f37f169e06d46a06589cef1d601dbc6 SHA512 90c555150b0fa86b88e4ba3360384edf6afa05d45b82b3260853178b77fd542da6f31bd2e80c8307380fff9c61f0230545ec987e6e74b8c3d708bc5ef5ca8f42
diff --git a/games-emulation/hatari/hatari-2.4.0.ebuild b/games-emulation/hatari/hatari-2.4.0.ebuild
deleted file mode 100644
index db2b63faf515..000000000000
--- a/games-emulation/hatari/hatari-2.4.0.ebuild
+++ /dev/null
@@ -1,98 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{8..11} )
-inherit cmake python-single-r1 xdg
-
-DESCRIPTION="Atari ST emulator"
-HOMEPAGE="https://hatari.tuxfamily.org/"
-SRC_URI="https://download.tuxfamily.org/hatari/${PV}/${P}.tar.bz2"
-
-LICENSE="GPL-2+"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="X capsimage gui png portmidi readline udev zlib"
-REQUIRED_USE="
-	${PYTHON_REQUIRED_USE}
-	png? ( zlib )"
-
-COMMON_DEPEND="
-	media-libs/libsdl2[X?,joystick,sound,video]
-	X? ( x11-libs/libX11 )
-	capsimage? ( >=dev-libs/spsdeclib-5.1-r1 )
-	png? ( media-libs/libpng:= )
-	portmidi? ( media-libs/portmidi )
-	readline? ( sys-libs/readline:= )
-	udev? ( virtual/udev )
-	zlib? ( sys-libs/zlib:= )"
-RDEPEND="
-	${PYTHON_DEPS}
-	${COMMON_DEPEND}
-	gui? (
-		$(python_gen_cond_dep 'dev-python/pygobject:3[${PYTHON_USEDEP}]')
-		x11-libs/gtk+:3[introspection]
-	)
-	>=games-emulation/emutos-1.1.1"
-DEPEND="
-	${COMMON_DEPEND}
-	X? ( x11-base/xorg-proto )"
-BDEPEND="${PYTHON_DEPS}"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-2.3.1-caps5-include-path.patch
-	"${FILESDIR}"/${PN}-2.3.1-cmake-include-checksym.patch
-)
-
-DOCS=(
-	readme.txt
-	doc/{bugs,changelog,scsi-driver,thanks,video-recording}.txt
-)
-
-src_prepare() {
-	cmake_src_prepare
-
-	sed -i "s/\.1\.gz\b/.1/;T;s/gzip[^\$]*/cat /" {*/,}*/CMakeLists.txt || die
-	sed -i "s:doc/${PN}:doc/${PF}/html:" python-ui/uihelpers.py || die
-	sed -e "s/python3/${EPYTHON}/" \
-		-e 's/mkdosfs/mkfs.fat/' \
-		-i tools/atari-hd-image.sh || die
-
-	# use emutos package rather than bundled ROM
-	rm src/tos.img || die
-	cat <<-EOF > hatari.cfg || die
-		[ROM]
-		szTosImageFileName = ${EPREFIX}/usr/share/emutos/etos1024k.img
-	EOF
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DBUILD_SHARED_LIBS=OFF
-		-DDOCDIR="${EPREFIX}"/usr/share/doc/${PF}/html
-		-DETCDIR="${EPREFIX}"/etc
-		$(cmake_use_find_package X X11)
-		$(cmake_use_find_package capsimage CapsImage)
-		$(cmake_use_find_package png PNG)
-		$(cmake_use_find_package portmidi PortMidi)
-		$(cmake_use_find_package readline Readline)
-		$(cmake_use_find_package udev Udev)
-		$(cmake_use_find_package zlib ZLIB)
-		$(usev !gui -DPYTHON_EXECUTABLE=false) # only disables python-ui/
-	)
-
-	cmake_src_configure
-}
-
-src_install() {
-	cmake_src_install
-
-	insinto /etc
-	doins hatari.cfg
-
-	mv "${ED}"/usr/share/doc/${PF}/{html/*.txt,} || die
-
-	python_fix_shebang "${ED}"/usr/bin
-	use gui && python_fix_shebang "${ED}"/usr/share/${PN}/${PN}ui
-}