1 files changed, 42 insertions, 0 deletions
diff --git a/games-puzzle/biniax2/biniax2-1.30-r1.ebuild b/games-puzzle/biniax2/biniax2-1.30-r1.ebuild
new file mode 100644
index 000000000000..e4710407e8e7
--- /dev/null
+++ b/games-puzzle/biniax2/biniax2-1.30-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit desktop
+
+DESCRIPTION="Logic game with arcade and tactics modes"
+HOMEPAGE="http://biniax.com/"
+SRC_URI="http://mordred.dir.bg/biniax/${P}-fullsrc.tar.gz"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND="media-libs/libsdl
+	media-libs/sdl-image[png]
+	media-libs/sdl-mixer[mod]"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}"
+
+src_prepare() {
+	default
+
+	rm -f data/Thumbs.db
+	sed -i \
+		-e "s:data/:/usr/share/${PN}/:" \
+		desktop/{gfx,snd}.c \
+		|| die
+	eapply \
+		"${FILESDIR}"/${P}-build.patch \
+		"${FILESDIR}"/${P}-dotfiles.patch
+}
+
+src_install() {
+	dobin ${PN}
+	insinto "/usr/share/${PN}"
+	doins -r data/*
+	doicon "${FILESDIR}"/${PN}.xpm
+	make_desktop_entry ${PN} Biniax-2
+}