1 files changed, 38 insertions, 0 deletions
diff --git a/games-puzzle/pipepanic/pipepanic-0.1.3-r3.ebuild b/games-puzzle/pipepanic/pipepanic-0.1.3-r3.ebuild
new file mode 100644
index 000000000000..f4ce26581c82
--- /dev/null
+++ b/games-puzzle/pipepanic/pipepanic-0.1.3-r3.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit desktop
+
+DESCRIPTION="A simple pipe connecting game"
+HOMEPAGE="http://www.users.waitrose.com/~thunor/pipepanic/"
+SRC_URI="http://www.users.waitrose.com/~thunor/pipepanic/dload/${P}-source.tar.gz"
+S="${WORKDIR}"/${P}-source
+
+LICENSE="GPL-2+ Free-Art-1.2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="media-libs/libsdl[video]"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+	eapply "${FILESDIR}"/${P}-gentoo.patch
+	# change harcoded data paths to match the install directory
+	sed -i \
+		-e "s:/opt/QtPalmtop/share/pipepanic/:/usr/share/${PN}/:" \
+		main.h \
+		|| die "sed failed"
+}
+
+src_install() {
+	dobin ${PN}
+
+	insinto /usr/share/${PN}
+	doins *.bmp
+	newicon PipepanicIcon64.png ${PN}.png
+	make_desktop_entry ${PN} "Pipepanic"
+	einstalldocs
+}