1 files changed, 0 insertions, 82 deletions
diff --git a/gnome-base/dconf/dconf-0.30.1.ebuild b/gnome-base/dconf/dconf-0.30.1.ebuild
deleted file mode 100644
index e52bab8ebd0a..000000000000
--- a/gnome-base/dconf/dconf-0.30.1.ebuild
+++ /dev/null
@@ -1,82 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-inherit bash-completion-r1 gnome.org gnome2-utils meson vala virtualx xdg
-
-DESCRIPTION="Simple low-level configuration system"
-HOMEPAGE="https://wiki.gnome.org/Projects/dconf"
-
-LICENSE="LGPL-2.1+"
-SLOT="0"
-KEYWORDS="alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 s390 ~sh sparc x86 ~x86-linux"
-IUSE="gtk-doc"
-
-RDEPEND="
-	>=dev-libs/glib-2.44.0:2
-	sys-apps/dbus
-"
-DEPEND="${RDEPEND}
-	$(vala_depend)
-	app-text/docbook-xml-dtd:4.2
-	app-text/docbook-xsl-stylesheets
-	dev-libs/libxslt
-	dev-util/gdbus-codegen
-	gtk-doc? ( >=dev-util/gtk-doc-1.15 )
-	>=sys-devel/gettext-0.19.8
-	virtual/pkgconfig
-	<dev-util/meson-0.52
-" # problem with meson-0.52+ https://gitlab.gnome.org/GNOME/dconf/issues/59
-
-PATCHES=(
-	"${FILESDIR}"/${PV}-bash-completion-dir.patch
-)
-
-src_prepare() {
-	xdg_src_prepare
-	vala_src_prepare
-}
-
-src_configure() {
-	local emesonargs=(
-		-Dbash_completion_dir="$(get_bashcompdir)"
-		-Dman=true
-		$(meson_use gtk-doc gtk_doc)
-	)
-	meson_src_configure
-}
-
-src_test() {
-	virtx meson_src_test
-}
-
-src_install() {
-	meson_src_install
-
-	# GSettings backend may be one of: memory, gconf, dconf
-	# Only dconf is really considered functional by upstream
-	# must have it enabled over gconf if both are installed
-	echo 'CONFIG_PROTECT_MASK="/etc/dconf"' >> 51dconf
-	echo 'GSETTINGS_BACKEND="dconf"' >> 51dconf
-	doenvd 51dconf
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-	gnome2_giomodule_cache_update
-
-	# Kill existing dconf-service processes as recommended by upstream due to
-	# possible changes in the dconf private dbus API.
-	# dconf-service will be dbus-activated on next use.
-	pids=$(pgrep -x dconf-service)
-	if [[ $? == 0 ]]; then
-		ebegin "Stopping dconf-service; it will automatically restart on demand"
-		kill ${pids}
-		eend $?
-	fi
-}
-
-pkg_postrm() {
-	xdg_pkg_postrm
-	gnome2_giomodule_cache_update
-}