2 files changed, 62 insertions, 0 deletions
diff --git a/gnome-extra/gnome-clocks/Manifest b/gnome-extra/gnome-clocks/Manifest
index 357428c34380..a85a59797e28 100644
--- a/gnome-extra/gnome-clocks/Manifest
+++ b/gnome-extra/gnome-clocks/Manifest
@@ -1 +1,2 @@
 DIST gnome-clocks-42.0.tar.xz 360968 BLAKE2B de66b802dbce8e57a97594c76e8fe5f7a4d65c1426d3c45217f3eb1e27e553fda9f1484b83827e6f44db10c8623581c7e1cd79f0bd79352966f67345e59fcf30 SHA512 f642cb4a626de2a97ad78c25922bb933bdac917d363097fcf5149310111abd11834410b48bfb4fc9cbae06f0ab30b0a5200d45304ce292b5a9558a90b922edb4
+DIST gnome-clocks-43.0.tar.xz 366872 BLAKE2B 1886d8e75b3d1b006a247bb044faf996d1788fdae65d4e825aeada1a2912bd6b58aa244da4088fd7f709c5a87fd788b92c45b9b116e462403d7929395cf0d6ac SHA512 703876a67000fa3a2b5e7bec70451a725aa4ed33aa2392a4c7fafc6ad287dd5591ee24c9aed20961739e9caa1f15ec404da9a2fa42e524dedaf75210d00b4fcf
diff --git a/gnome-extra/gnome-clocks/gnome-clocks-43.0.ebuild b/gnome-extra/gnome-clocks/gnome-clocks-43.0.ebuild
new file mode 100644
index 000000000000..3bbb0eff77cd
--- /dev/null
+++ b/gnome-extra/gnome-clocks/gnome-clocks-43.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson vala xdg
+
+DESCRIPTION="Clocks application for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Clocks https://gitlab.gnome.org/GNOME/gnome-clocks"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.68:2
+	>=gui-libs/gtk-4.5:4
+	>=media-libs/gsound-0.98
+	>=dev-libs/libgweather-4.2.0:4=
+	gnome-base/gnome-desktop:4=
+	>=sci-geosciences/geocode-glib-1:2
+	>=app-misc/geoclue-2.4:2.0
+	>=gui-libs/libadwaita-1.2:1
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	$(vala_depend)
+	>=dev-libs/libgweather-4.2.0:4[vala]
+	media-libs/gsound[vala]
+	gui-libs/libadwaita:1[vala]
+"
+
+DOCS=( AUTHORS.md CONTRIBUTING.md README.md )
+
+src_prepare() {
+	default
+	vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dprofile=default
+		-Ddocs=false
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}