1 files changed, 49 insertions, 0 deletions
diff --git a/kde-frameworks/bluez-qt/bluez-qt-5.109.0.ebuild b/kde-frameworks/bluez-qt/bluez-qt-5.109.0.ebuild
new file mode 100644
index 000000000000..21a0b1e284d1
--- /dev/null
+++ b/kde-frameworks/bluez-qt/bluez-qt-5.109.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+QTMIN=5.15.9
+VIRTUALX_REQUIRED="test" # bug 910062 (tests hang)
+inherit ecm frameworks.kde.org udev
+
+DESCRIPTION="Qt wrapper for Bluez 5 DBus API"
+
+LICENSE="LGPL-2"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~riscv"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DUDEV_RULES_INSTALL_DIR="$(get_udevdir)/rules.d"
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# parallel tests fail, bug 609248; managertest hangs, bug 668196
+	local myctestargs=(
+		-j1
+		-E "(managertest)"
+	)
+
+	ecm_src_test
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+	udev_reload
+}
+
+pkg_postrm() {
+	ecm_pkg_postrm
+	udev_reload
+}