1 files changed, 47 insertions, 0 deletions
diff --git a/lxqt-base/liblxqt/liblxqt-1.0.0.ebuild b/lxqt-base/liblxqt/liblxqt-1.0.0.ebuild
new file mode 100644
index 000000000000..b3fc0d901392
--- /dev/null
+++ b/lxqt-base/liblxqt/liblxqt-1.0.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="Common base library for the LXQt desktop environment"
+HOMEPAGE="https://lxqt.github.io/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="LGPL-2.1+ BSD"
+SLOT="0/$(ver_cut 1-2)"
+IUSE="+backlight"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	>=dev-util/lxqt-build-tools-0.10.0
+"
+DEPEND="
+	>=dev-libs/libqtxdg-3.8.0
+	>=dev-qt/qtcore-5.15:5
+	>=dev-qt/qtdbus-5.15:5
+	>=dev-qt/qtgui-5.15:5
+	>=dev-qt/qtwidgets-5.15:5
+	>=dev-qt/qtx11extras-5.15:5
+	>=dev-qt/qtxml-5.15:5
+	kde-frameworks/kwindowsystem:5[X]
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	backlight? ( sys-auth/polkit-qt )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_BACKLIGHT_LINUX_BACKEND=$(usex backlight)
+	)
+	cmake_src_configure
+}