summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'media-fonts/noto-emoji/noto-emoji-20200311.ebuild')
-rw-r--r--media-fonts/noto-emoji/noto-emoji-20200311.ebuild65
1 files changed, 65 insertions, 0 deletions
diff --git a/media-fonts/noto-emoji/noto-emoji-20200311.ebuild b/media-fonts/noto-emoji/noto-emoji-20200311.ebuild
new file mode 100644
index 00000000000..273566fce3e
--- /dev/null
+++ b/media-fonts/noto-emoji/noto-emoji-20200311.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit font python-any-r1
+
+DESCRIPTION="Google Noto Emoji fonts"
+HOMEPAGE="https://www.google.com/get/noto/ https://github.com/googlei18n/noto-emoji"
+
+COMMIT="4325631b45027a3d4da9a0f08f829e790f86ff4d"
+SRC_URI="https://github.com/googlei18n/noto-emoji/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+DEPEND="${PYTHON_DEPS}
+ app-arch/zopfli
+ $(python_gen_any_dep '
+ dev-python/fonttools[${PYTHON_USEDEP}]
+ dev-python/nototools[${PYTHON_USEDEP}]
+ ')
+ media-gfx/pngquant
+ x11-libs/cairo
+ || ( media-gfx/imagemagick[png] media-gfx/graphicsmagick[png] )
+"
+RDEPEND=""
+
+RESTRICT="binchecks strip"
+
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+FONT_S="${S}"
+FONT_SUFFIX="ttf"
+
+PATCHES=(
+ # From Fedora
+ "${FILESDIR}/${PN}-build-all-flags.patch"
+
+ # https://github.com/googlei18n/noto-emoji/issues/240
+ "${FILESDIR}/${PN}-20180823-build-path.patch"
+)
+
+src_prepare() {
+ default
+
+ # Based on Fedora patch to allow graphicsmagick usage
+ if has_version media-gfx/graphicsmagick; then
+ eapply "${FILESDIR}/${PN}-20190328-use-gm.patch"
+ fi
+}
+
+src_install() {
+ font_src_install
+
+ # Don't lose fancy emoji icons
+ insinto /usr/share/icons/"${PN}"/128x128/emotes/
+ doins png/128/*.png
+
+ insinto /usr/share/icons/"${PN}"/scalable/emotes/
+ doins svg/*.svg
+}