1 files changed, 47 insertions, 0 deletions
diff --git a/media-gfx/flameshot/flameshot-12.0.0-r2.ebuild b/media-gfx/flameshot/flameshot-12.0.0-r2.ebuild
new file mode 100644
index 000000000000..708edafe52aa
--- /dev/null
+++ b/media-gfx/flameshot/flameshot-12.0.0-r2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 2021-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="Powerful yet simple to use screenshot software"
+HOMEPAGE="https://flameshot.org https://github.com/flameshot-org/flameshot"
+SRC_URI="https://github.com/flameshot-org/flameshot/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0 Free-Art-1.3 GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="wayland"
+
+DEPEND="
+	=dev-qt/qtsingleapplication-2.6*[qt5(+),X]
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	sys-apps/dbus
+	wayland? ( kde-frameworks/kguiaddons:5 )
+"
+BDEPEND="
+	dev-qt/linguist-tools:5
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	rm -r external/singleapplication || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_EXTERNAL_SINGLEAPPLICATION=1
+		-DENABLE_CACHE=0
+		-DUSE_WAYLAND_CLIPBOARD=$(usex wayland)
+	)
+
+	cmake_src_configure
+}