1 files changed, 48 insertions, 0 deletions
diff --git a/media-gfx/phototonic/phototonic-2.0.ebuild b/media-gfx/phototonic/phototonic-2.0.ebuild
new file mode 100644
index 000000000000..46087619b847
--- /dev/null
+++ b/media-gfx/phototonic/phototonic-2.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit gnome2-utils qmake-utils xdg-utils
+
+DESCRIPTION="Image viewer and organizer"
+HOMEPAGE="https://github.com/oferkv/phototonic"
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/oferkv/phototonic.git"
+else
+	SRC_URI="https://github.com/oferkv/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="svg tiff"
+
+RDEPEND="
+	dev-qt/qtwidgets:5
+	dev-qt/qtgui:5
+	dev-qt/qtcore:5
+	media-gfx/exiv2:=
+	svg? ( dev-qt/qtsvg:5 )
+	tiff? ( dev-qt/qtimageformats:5 )
+"
+DEPEND="${RDEPEND}"
+
+src_configure() {
+	eqmake5
+}
+
+src_install() {
+	emake install INSTALL_ROOT="${D}"
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}