1 files changed, 0 insertions, 76 deletions
diff --git a/media-gfx/prusaslicer/prusaslicer-2.4.0-r1.ebuild b/media-gfx/prusaslicer/prusaslicer-2.4.0-r1.ebuild
deleted file mode 100644
index 51a5b4378a17..000000000000
--- a/media-gfx/prusaslicer/prusaslicer-2.4.0-r1.ebuild
+++ /dev/null
@@ -1,76 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-WX_GTK_VER="3.0-gtk3"
-
-inherit cmake desktop wxwidgets xdg
-
-MY_PN="PrusaSlicer"
-
-DESCRIPTION="A mesh slicer to generate G-code for fused-filament-fabrication (3D printers)"
-HOMEPAGE="https://www.prusa3d.com/prusaslicer/"
-SRC_URI="https://github.com/prusa3d/${MY_PN}/archive/version_${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="AGPL-3 Boost-1.0 GPL-2 LGPL-3 MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="test"
-
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	dev-cpp/eigen:3
-	>=dev-cpp/tbb-2021.4.0
-	>=dev-libs/boost-1.73.0:=[nls,threads(+)]
-	dev-libs/cereal
-	dev-libs/expat
-	dev-libs/glib:2
-	dev-libs/gmp:=
-	dev-libs/mpfr:=
-	>=media-gfx/openvdb-8.2
-	net-misc/curl
-	media-libs/glew:0=
-	media-libs/ilmbase:=
-	media-libs/libpng:0=
-	media-libs/qhull:=
-	sci-libs/libigl
-	sci-libs/nlopt
-	>=sci-mathematics/cgal-5.0:=
-	sys-apps/dbus
-	sys-libs/zlib:=
-	virtual/glu
-	virtual/opengl
-	x11-libs/gtk+:3
-	x11-libs/wxGTK:${WX_GTK_VER}[X,opengl]
-"
-DEPEND="${RDEPEND}
-	media-libs/qhull[static-libs]
-"
-
-S="${WORKDIR}/${MY_PN}-version_${PV}"
-
-src_prepare() {
-	sed -i -e 's/PrusaSlicer-${SLIC3R_VERSION}+UNKNOWN/PrusaSlicer-${SLIC3R_VERSION}+Gentoo/g' version.inc || die
-	cmake_src_prepare
-}
-
-src_configure() {
-	CMAKE_BUILD_TYPE="Release"
-
-	setup-wxwidgets
-
-	local mycmakeargs=(
-		-DSLIC3R_BUILD_TESTS=$(usex test)
-		-DSLIC3R_FHS=ON
-		-DSLIC3R_GTK=3
-		-DSLIC3R_GUI=ON
-		-DSLIC3R_PCH=OFF
-		-DSLIC3R_STATIC=OFF
-		-DSLIC3R_WX_STABLE=ON
-		-Wno-dev
-	)
-
-	cmake_src_configure
-}