1 files changed, 43 insertions, 0 deletions
diff --git a/media-libs/ctl/ctl-1.5.3.ebuild b/media-libs/ctl/ctl-1.5.3.ebuild
new file mode 100644
index 000000000000..11e4fd2a2845
--- /dev/null
+++ b/media-libs/ctl/ctl-1.5.3.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+MY_COMMIT=3fc4ae7a8af35d380654e573d895216fd5ba407e
+
+DESCRIPTION="AMPAS' Color Transformation Language"
+HOMEPAGE="https://github.com/ampas/CTL"
+SRC_URI="https://github.com/ampas/CTL/archive/${P}.tar.gz"
+S="${WORKDIR}/CTL-${P}"
+
+LICENSE="AMPAS"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/imath:=
+	>=media-libs/openexr-3:=[threads]
+	media-libs/tiff:=
+	!media-libs/openexr_ctl"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_configure() {
+	# -Werror=strict-aliasing
+	# https://bugs.gentoo.org/926823
+	# https://github.com/ampas/CTL/issues/146
+	append-flags -fno-strict-aliasing
+	filter-lto
+
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_DOCDIR="share/doc/${PF}"
+		-DCTL_BUILD_TESTS=$(usex test)
+		-DCTL_BUILD_TOOLS=ON
+	)
+	cmake_src_configure
+}