1 files changed, 0 insertions, 182 deletions
diff --git a/media-libs/fontconfig/fontconfig-2.13.1-r2.ebuild b/media-libs/fontconfig/fontconfig-2.13.1-r2.ebuild
deleted file mode 100644
index 6b51d5adc5b4..000000000000
--- a/media-libs/fontconfig/fontconfig-2.13.1-r2.ebuild
+++ /dev/null
@@ -1,182 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit autotools multilib-minimal readme.gentoo-r1
-
-DESCRIPTION="A library for configuring and customizing font access"
-HOMEPAGE="https://fontconfig.org/"
-SRC_URI="https://fontconfig.org/release/${P}.tar.bz2"
-
-LICENSE="MIT"
-SLOT="1.0"
-[[ $(ver_cut 3) -ge 90 ]] || \
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
-IUSE="doc static-libs"
-
-# Test test-bz106632 is known to be broken, see bug #751232
-# and would require several backports. It will be fixed in
-# next version.
-# check-missing-doc is known to be broken, see bug #733608
-# because fontconfig-2.13.1-static_build.patch introduces a
-# function FcStrBuildFilename which is lacking documentation.
-# However, backporting isn't worth it. Will be fixed in
-# next version.
-RESTRICT="test"
-
-BDEPEND="dev-util/gperf
-	>=sys-devel/gettext-0.19.8
-	virtual/pkgconfig
-	doc? (
-		=app-text/docbook-sgml-dtd-3.1*
-		app-text/docbook-sgml-utils[jadetex]
-	)"
-# Purposefully dropped the xml USE flag and libxml2 support.  Expat is the
-# default and used by every distro.  See bug #283191.
-RDEPEND=">=dev-libs/expat-2.1.0-r3[${MULTILIB_USEDEP}]
-	>=media-libs/freetype-2.9[${MULTILIB_USEDEP}]
-	!elibc_Darwin? ( !elibc_SunOS? ( sys-apps/util-linux[${MULTILIB_USEDEP}] ) )
-	elibc_Darwin? ( sys-libs/native-uuid )
-	elibc_SunOS? ( sys-libs/libuuid )
-	virtual/libintl[${MULTILIB_USEDEP}]"
-DEPEND="${RDEPEND}"
-PDEPEND="!x86-winnt? ( app-eselect/eselect-fontconfig )
-	virtual/ttf-fonts"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-2.10.2-docbook.patch # 310157
-	"${FILESDIR}"/${PN}-2.12.3-latin-update.patch # 130466 + make liberation default
-	"${FILESDIR}"/${P}-revert_delete_.uuid_for_empty_directory.patch # 666418
-
-	# Patches from upstream (can usually be removed with next version bump)
-	"${FILESDIR}"/${P}-static_build.patch
-	"${FILESDIR}"/${P}-proper_homedir.patch
-)
-
-MULTILIB_CHOST_TOOLS=( /usr/bin/fc-cache$(get_exeext) )
-
-pkg_setup() {
-	DOC_CONTENTS="Please make fontconfig configuration changes using
-	\`eselect fontconfig\`. Any changes made to /etc/fonts/fonts.conf will be
-	overwritten. If you need to reset your configuration to upstream defaults,
-	delete the directory ${EROOT}/etc/fonts/conf.d/ and re-emerge fontconfig."
-}
-
-src_prepare() {
-	default
-	eautoreconf
-}
-
-multilib_src_configure() {
-	local addfonts
-	# harvest some font locations, such that users can benefit from the
-	# host OS's installed fonts
-	case ${CHOST} in
-		*-darwin*)
-			addfonts=",/Library/Fonts,/System/Library/Fonts"
-		;;
-		*-solaris*)
-			[[ -d /usr/X/lib/X11/fonts/TrueType ]] && \
-				addfonts=",/usr/X/lib/X11/fonts/TrueType"
-			[[ -d /usr/X/lib/X11/fonts/Type1 ]] && \
-				addfonts="${addfonts},/usr/X/lib/X11/fonts/Type1"
-		;;
-		*-linux-gnu)
-			use prefix && [[ -d /usr/share/fonts ]] && \
-				addfonts=",/usr/share/fonts"
-		;;
-	esac
-
-	local myeconfargs=(
-		$(use_enable doc docbook)
-		$(use_enable static-libs static)
-		--enable-docs
-		--localstatedir="${EPREFIX}"/var
-		--with-default-fonts="${EPREFIX}"/usr/share/fonts
-		--with-add-fonts="${EPREFIX}/usr/local/share/fonts${addfonts}"
-		--with-templatedir="${EPREFIX}"/etc/fonts/conf.avail
-	)
-
-	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
-}
-
-multilib_src_install() {
-	default
-
-	# avoid calling this multiple times, bug #459210
-	if multilib_is_native_abi; then
-		# stuff installed from build-dir
-		emake -C doc DESTDIR="${D}" install-man
-
-		insinto /etc/fonts
-		doins fonts.conf
-	fi
-}
-
-multilib_src_install_all() {
-	einstalldocs
-	find "${ED}" -name "*.la" -delete || die
-
-	# fc-lang directory contains language coverage datafiles
-	# which are needed to test the coverage of fonts.
-	insinto /usr/share/fc-lang
-	doins fc-lang/*.orth
-
-	dodoc doc/fontconfig-user.{txt,pdf}
-
-	if [[ -e ${ED}/usr/share/doc/fontconfig/ ]];  then
-		mv "${ED}"/usr/share/doc/fontconfig/* "${ED}"/usr/share/doc/${P} || die
-		rm -rf "${ED}"/usr/share/doc/fontconfig
-	fi
-
-	# Changes should be made to /etc/fonts/local.conf, and as we had
-	# too much problems with broken fonts.conf we force update it ...
-	echo 'CONFIG_PROTECT_MASK="/etc/fonts/fonts.conf"' > "${T}"/37fontconfig
-	doenvd "${T}"/37fontconfig
-
-	# As of fontconfig 2.7, everything sticks their noses in here.
-	dodir /etc/sandbox.d
-	echo 'SANDBOX_PREDICT="/var/cache/fontconfig"' > "${ED}"/etc/sandbox.d/37fontconfig
-
-	readme.gentoo_create_doc
-
-	keepdir /var/cache/${PN}
-}
-
-pkg_preinst() {
-	# Bug #193476
-	# /etc/fonts/conf.d/ contains symlinks to ../conf.avail/ to include various
-	# config files.  If we install as-is, we'll blow away user settings.
-	ebegin "Syncing fontconfig configuration to system"
-	if [[ -e ${EROOT}/etc/fonts/conf.d ]]; then
-		for file in "${EROOT}"/etc/fonts/conf.avail/*; do
-			f=${file##*/}
-			if [[ -L ${EROOT}/etc/fonts/conf.d/${f} ]]; then
-				[[ -f ${ED}/etc/fonts/conf.avail/${f} ]] \
-					&& ln -sf ../conf.avail/"${f}" "${ED}"/etc/fonts/conf.d/ &>/dev/null
-			else
-				[[ -f ${ED}/etc/fonts/conf.avail/${f} ]] \
-					&& rm "${ED}"/etc/fonts/conf.d/"${f}" &>/dev/null
-			fi
-		done
-	fi
-	eend $?
-}
-
-pkg_postinst() {
-	einfo "Cleaning broken symlinks in ${EROOT}/etc/fonts/conf.d/"
-	find -L "${EROOT}"/etc/fonts/conf.d/ -type l -delete
-
-	readme.gentoo_print_elog
-
-	if [[ ${ROOT} == "" ]]; then
-		multilib_pkg_postinst() {
-			ebegin "Creating global font cache for ${ABI}"
-			"${EPREFIX}"/usr/bin/${CHOST}-fc-cache -srf
-			eend $?
-		}
-
-		multilib_parallel_foreach_abi multilib_pkg_postinst
-	fi
-}