1 files changed, 51 insertions, 0 deletions
diff --git a/media-libs/kimageannotator/kimageannotator-0.4.0.ebuild b/media-libs/kimageannotator/kimageannotator-0.4.0.ebuild
new file mode 100644
index 000000000000..417b4bc23c2d
--- /dev/null
+++ b/media-libs/kimageannotator/kimageannotator-0.4.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+VIRTUALX_REQUIRED="test"
+inherit cmake virtualx
+
+MY_PN=kImageAnnotator
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Tool for annotating images"
+HOMEPAGE="https://github.com/ksnip/kImageAnnotator"
+SRC_URI="https://github.com/ksnip/${MY_PN}/archive/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5[png]
+	>=media-libs/kcolorpicker-0.1.4
+	x11-libs/libX11
+"
+DEPEND="${RDEPEND}
+	test? ( dev-qt/qttest:5 )
+"
+BDEPEND="
+	dev-qt/linguist-tools:5
+"
+PATCHES=(
+	# https://github.com/ksnip/kImageAnnotator/pull/195
+	"${FILESDIR}/${P}-fix-static-test-library-PR195.patch"
+)
+
+S="${WORKDIR}/${MY_P}"
+
+src_configure() {
+	local mycmakeargs+=(
+		-DBUILD_TESTS=$(usex test)
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	virtx cmake_src_test
+}