1 files changed, 69 insertions, 0 deletions
diff --git a/media-libs/lib3mf/lib3mf-2.1.1-r1.ebuild b/media-libs/lib3mf/lib3mf-2.1.1-r1.ebuild
new file mode 100644
index 000000000000..fb5acbc060c8
--- /dev/null
+++ b/media-libs/lib3mf/lib3mf-2.1.1-r1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake eapi8-dosym
+
+DESCRIPTION="Implementation of the 3D Manufacturing Format file standard"
+HOMEPAGE="https://3mf.io/ https://github.com/3MFConsortium/lib3mf"
+SRC_URI="https://github.com/3MFConsortium/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/2"
+# the included ACT binary is a statically x86_64 built one
+# see https://github.com/3MFConsortium/lib3mf/issues/199
+# Keyword arm64 can be re-added after we have dev-go/act
+# package keyworded
+KEYWORDS="~amd64 ~x86"
+IUSE="+system-act test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/libzip:=
+	sys-apps/util-linux
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	system-act? ( dev-go/act )
+	test? (
+		dev-cpp/gtest
+		dev-libs/openssl
+		dev-util/valgrind
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.1.0-0001-Gentoo-specific-avoid-pre-stripping-library.patch
+	"${FILESDIR}"/${P}-0001-patch-to-use-system-provided-act-binary.patch
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_INCLUDEDIR="include/${PN}"
+		-DLIB3MF_TESTS=$(usex test)
+		-DUSE_INCLUDED_LIBZIP=OFF
+		-DUSE_INCLUDED_ZLIB=OFF
+		-DUSE_SYSTEM_ACT=$(usex system-act)
+	)
+
+	if use test; then
+		mycmakeargs+=(
+			-DUSE_INCLUDED_GTEST=OFF
+			# code says it uses libressl, but works with openssl too
+			-DUSE_INCLUDED_SSL=OFF
+		)
+	fi
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	for suf in abi types implicit; do
+		dosym8 -r /usr/include/${PN}/Bindings/Cpp/${PN}_${suf}.hpp /usr/include/${PN}/${PN}_${suf}.hpp
+	done
+}