2 files changed, 93 insertions, 0 deletions
diff --git a/media-libs/libmediainfo/Manifest b/media-libs/libmediainfo/Manifest
index 17074849a60d..45dcfa6b5e1c 100644
--- a/media-libs/libmediainfo/Manifest
+++ b/media-libs/libmediainfo/Manifest
@@ -1 +1,2 @@
 DIST libmediainfo_22.09.tar.xz 1886180 BLAKE2B 3b9fa03ae1fafd06e494ad462ab30a19141c516b6fe61867da7cf339ee470cb56a6cdab57c4e8a498e79c7e3e4b4e5a19b4302f2db2ab0172fe26fefcc0a92f6 SHA512 4204f0ad73f5b826ec89df88607d7e491ecdad512c6bdae12f72b551827b1e4818aa2b88a46a46cb1f8fca46f3638fbe0243e252c685ca46b2d33a9acb00198c
+DIST libmediainfo_23.03.tar.xz 1925904 BLAKE2B bd8d716e9e85bdf2c91ddb6b5492e87e75e497469107aa3ca8a045f25bca1202432a2c8e9a01d179afc1d705ad4c35fcc41cda44cf2b9e57bffd0e8db4f2b7c0 SHA512 a13c4042851248ee4c76f2f52bbafe6e2152e99d60d8cccbff3c5aa01c63e27f97c3335cf88bdaa4869a1f1550ed9ce428af127569ee09c2fee344ed06e44942
diff --git a/media-libs/libmediainfo/libmediainfo-23.03.ebuild b/media-libs/libmediainfo/libmediainfo-23.03.ebuild
new file mode 100644
index 000000000000..1118b3bbb2c3
--- /dev/null
+++ b/media-libs/libmediainfo/libmediainfo-23.03.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# These must be bumped together:
+# - media-libs/libzen (if a release is available)
+# - media-libs/libmediainfo
+# - media-video/mediainfo
+
+MY_PN="MediaInfo"
+inherit autotools edos2unix flag-o-matic
+
+DESCRIPTION="MediaInfo libraries"
+HOMEPAGE="https://mediaarea.net/mediainfo/ https://github.com/MediaArea/MediaInfoLib"
+SRC_URI="https://mediaarea.net/download/source/${PN}/${PV}/${P/-/_}.tar.xz"
+S="${WORKDIR}"/${MY_PN}Lib/Project/GNU/Library
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="curl doc mms"
+
+# Tests try to fetch data from online sources
+RESTRICT="test"
+
+# The libzen dep usually needs to be bumped for each release!
+RDEPEND="
+	dev-libs/tinyxml2:=
+	>=media-libs/libzen-0.4.41
+	sys-libs/zlib
+	curl? ( net-misc/curl )
+	mms? ( >=media-libs/libmms-0.6.1 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+
+src_prepare() {
+	default
+
+	sed -i 's:-O2::' configure.ac || die
+
+	append-cppflags -DMEDIAINFO_LIBMMS_DESCRIBE_SUPPORT=0
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-shared \
+		--disable-static \
+		--disable-staticlibs \
+		--with-libtinyxml2 \
+		$(use_with curl libcurl) \
+		$(use_with mms libmms)
+}
+
+src_compile() {
+	default
+
+	if use doc; then
+		cd "${WORKDIR}"/${MY_PN}Lib/Source/Doc || die
+		doxygen Doxyfile || die
+	fi
+}
+
+src_install() {
+	if use doc; then
+		local HTML_DOCS=( "${WORKDIR}"/${MY_PN}Lib/Doc/*.html )
+	fi
+
+	default
+
+	edos2unix ${PN}.pc #414545
+	insinto /usr/$(get_libdir)/pkgconfig
+	doins ${PN}.pc
+
+	for x in ./ Archive Audio Duplicate Export Image Multiple Reader Tag Text Video; do
+		insinto /usr/include/${MY_PN}/${x}
+		doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}/${x}/*.h
+	done
+
+	insinto /usr/include/${MY_PN}DLL
+	doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}DLL/*.h
+
+	dodoc "${WORKDIR}"/${MY_PN}Lib/*.txt
+
+	find "${ED}" -name '*.la' -delete || die
+}