1 files changed, 40 insertions, 0 deletions
diff --git a/media-libs/libmygpo-qt/libmygpo-qt-1.0.9_p20180307.ebuild b/media-libs/libmygpo-qt/libmygpo-qt-1.0.9_p20180307.ebuild
new file mode 100644
index 000000000000..f528099bacff
--- /dev/null
+++ b/media-libs/libmygpo-qt/libmygpo-qt-1.0.9_p20180307.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+COMMIT=28c492b6b789ba1c3c292995a52fe4e456268182
+inherit cmake-utils vcs-snapshot
+
+DESCRIPTION="Qt/C++ library wrapping the gpodder.net webservice"
+HOMEPAGE="http://wiki.gpodder.org/wiki/Libmygpo-qt"
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/gpodder/libmygpo-qt.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/gpodder/${PN}/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="test"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtnetwork:5
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	test? ( dev-qt/qttest:5 )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_WITH_QT4=OFF
+		-DMYGPO_BUILD_TESTS=$(usex test)
+	)
+
+	cmake-utils_src_configure
+}