1 files changed, 49 insertions, 0 deletions
diff --git a/media-libs/libsamplerate/libsamplerate-0.2.2.ebuild b/media-libs/libsamplerate/libsamplerate-0.2.2.ebuild
new file mode 100644
index 000000000000..698fa623a51a
--- /dev/null
+++ b/media-libs/libsamplerate/libsamplerate-0.2.2.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit multilib-minimal
+
+DESCRIPTION="Secret Rabbit Code (aka libsamplerate) is a Sample Rate Converter for audio"
+HOMEPAGE="https://libsndfile.github.io/libsamplerate/"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="https://github.com/libsndfile/libsamplerate.git"
+else
+	SRC_URI="https://github.com/libsndfile/libsamplerate/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+fi
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+# Alsa/FFTW are only required for tests
+# libsndfile is only used by examples and tests
+DEPEND="
+	test? (
+		media-libs/alsa-lib[${MULTILIB_USEDEP}]
+		media-libs/libsndfile[${MULTILIB_USEDEP}]
+		sci-libs/fftw:3.0[${MULTILIB_USEDEP}]
+	)"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+	[[ ${PV} == *9999 ]] && eautoreconf
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		$(use_enable test alsa) \
+		$(use_enable test fftw) \
+		$(use_enable test sndfile)
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${ED}" -name '*.la' -type f -delete || die
+}