1 files changed, 51 insertions, 0 deletions
diff --git a/media-plugins/vdr-imonlcd/vdr-imonlcd-1.0.3.ebuild b/media-plugins/vdr-imonlcd/vdr-imonlcd-1.0.3.ebuild
new file mode 100644
index 000000000000..05e6d56bd235
--- /dev/null
+++ b/media-plugins/vdr-imonlcd/vdr-imonlcd-1.0.3.ebuild
@@ -0,0 +1,51 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit linux-info toolchain-funcs udev vdr-plugin-2
+
+DESCRIPTION="VDR Plugin: shows information about the current state of VDR on iMON LCD"
+HOMEPAGE="https://projects.vdr-developer.org/projects/plg-imonlcd/wiki"
+SRC_URI="https://github.com/vdr-projects/vdr-plugin-imonlcd/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/vdr-plugin-imonlcd-${PV}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	media-libs/freetype
+	virtual/udev"
+DEPEND="${RDEPEND}
+	media-video/vdr"
+BDEPEND="virtual/pkgconfig"
+QA_FLAGS_IGNORED="
+	usr/lib/vdr/plugins/libvdr-.*
+	usr/lib64/vdr/plugins/libvdr-.*"
+DOCS=(
+	HISTORY
+	README
+)
+CONFIG_CHECK="~IR_IMON"
+
+pkg_setup() {
+	linux-info_pkg_setup
+	vdr-plugin-2_pkg_setup
+}
+
+src_configure() {
+	tc-export PKG_CONFIG
+	default
+}
+
+src_install() {
+	rm README.git || die
+	vdr-plugin-2_src_install
+
+	udev_dorules "${FILESDIR}"/99-imonlcd.rules
+}
+
+pkg_postinst() {
+	udev_reload
+}