1 files changed, 44 insertions, 50 deletions

diff --git a/media-video/libva-utils/libva-utils-9999.ebuild b/media-video/libva-utils/libva-utils-9999.ebuild
index 0155912ee582..061e8bcaf812 100644
--- a/media-video/libva-utils/libva-utils-9999.ebuild
+++ b/media-video/libva-utils/libva-utils-9999.ebuild
@@ -1,97 +1,91 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
-inherit autotools
+inherit meson
 
 DESCRIPTION="Collection of utilities and tests for VA-API"
-HOMEPAGE="https://01.org/linuxmedia/vaapi"
+HOMEPAGE="https://github.com/intel/libva-utils"
 if [[ ${PV} = *9999 ]] ; then
 	inherit git-r3
 	EGIT_REPO_URI="https://github.com/intel/libva-utils"
 else
-	# Tarball with pre-built 'configure' not always available, portage use tarballs
-	# without pre-built 'configure' as they are always avaialbe upstream.
-	# SRC_URI="https://github.com/intel/libva-utils/releases/download/${PV}/${P}.tar.bz2"
 	SRC_URI="https://github.com/intel/libva-utils/archive/${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+	KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
 fi
 
 LICENSE="MIT"
 SLOT="0"
-IUSE="+drm examples putsurface test test-va-api +vainfo wayland X"
-RESTRICT="!test? ( test )"
+IUSE="examples putsurface test +vainfo wayland X"
+RESTRICT="test" # Tests must be run manually
 
 REQUIRED_USE="
-	|| ( drm wayland X )
 	putsurface? ( || ( wayland X ) )
-	putsurface? ( drm )
-	|| ( examples putsurface test-va-api vainfo )
+	|| ( examples putsurface test vainfo )
 "
 
-BDEPEND="virtual/pkgconfig"
-
-if [[ ${PV} = *9999 ]] ; then
-	DEPEND="~x11-libs/libva-${PV}:=[drm?,wayland?,X?]"
-else
-	DEPEND=">=x11-libs/libva-$(ver_cut 1-2).0:=[drm?,wayland?,X?]"
-fi
-
-DEPEND+="
+DEPEND="
+	x11-libs/libdrm
 	wayland? ( >=dev-libs/wayland-1.0.6 )
 	X? ( >=x11-libs/libX11-1.6.2 )
 "
+if [[ ${PV} = *9999 ]] ; then
+	DEPEND+="~media-libs/libva-${PV}:=[wayland?,X?]"
+else
+	DEPEND+=">=media-libs/libva-$(ver_cut 1-2).0:=[wayland?,X?]"
+fi
 RDEPEND="${DEPEND}"
-
-PATCHES=( "${FILESDIR}/${PN}-2.10.0_test_in_sandbox.patch" )
-
-# CONTRIBUTING.md and README.md are avaialbe only in .tar.gz tarballs and in git
-DOCS=( NEWS CONTRIBUTING.md README.md )
+BDEPEND="virtual/pkgconfig"
 
 src_prepare() {
 	default
 
-	sed -e 's/-Werror//' -i test/Makefile.am || die
+	local sed_args=()
 
 	if ! use examples ; then
-		sed -E -e '/^SUBDIRS \+?=/s!( decode\>| encode\>| videoprocess\>| vendor/intel\>| vendor/intel/sfcsample\>)!!g' -i Makefile.am || die
+		sed_args+=(
+			-e "/^  subdir('decode')$/d"
+			-e "/^  subdir('encode')$/d"
+			-e "/^  subdir('videoprocess')$/d"
+			-e "/^  subdir('vendor\/intel')$/d"
+			-e "/^  subdir('vendor\/intel\/sfcsample')$/d"
+		)
 	fi
 
 	if ! use putsurface ; then
-		sed -E -e '/^SUBDIRS \+?=/s! putsurface\>!!g' -i Makefile.am || die
+		sed_args+=(-e "/^  subdir('putsurface')$/d")
 	fi
 
 	if ! use vainfo ; then
-		sed -E -e '/^SUBDIRS \+?=/s! vainfo\>!!g' -i Makefile.am || die
+		sed_args+=(-e "/^subdir('vainfo')$/d")
 	fi
 
-	eautoreconf
+	if [[ ${#sed_args[@]} -gt 0 ]] ; then
+		sed "${sed_args[@]}" -i meson.build || die
+	fi
 }
 
 src_configure() {
-	local myeconfargs=(
-		$(use_enable drm)
-		$(use_enable test tests)
-		$(use_enable wayland)
-		$(use_enable X x11)
+	local emesonargs=(
+		-Ddrm=true
+		$(meson_use X x11)
+		$(meson_use wayland)
+		$(meson_use test tests)
 	)
-
-	if use test || use test-va-api ; then
-		myeconfargs+=( --enable-tests )
-	else
-		myeconfargs+=( --disable-tests )
-	fi
-
-	econf "${myeconfargs[@]}"
+	meson_src_configure
 }
 
 src_install() {
-	default
+	meson_src_install
+
+	if ! use test ; then
+		rm -f "${ED}"/usr/bin/test_va_api || die
+	fi
+}
 
-	if ! use test-va-api ; then
-		if [[ -e "${ED}"/usr/bin/test_va_api ]] ; then
-			rm -f "${ED}"/usr/bin/test_va_api || die
-		fi
+pkg_postinst() {
+	if use test ; then
+		elog "Tests must be run manually with the test_va_api binary"
 	fi
 }