1 files changed, 67 insertions, 0 deletions
diff --git a/net-libs/libtrace/libtrace-4.0.20.ebuild b/net-libs/libtrace/libtrace-4.0.20.ebuild
new file mode 100644
index 000000000000..fcc866df083d
--- /dev/null
+++ b/net-libs/libtrace/libtrace-4.0.20.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="A library and tools for trace processing"
+HOMEPAGE="https://github.com/LibtraceTeam/libtrace"
+SRC_URI="https://github.com/LibtraceTeam/libtrace/archive/refs/tags/${PV}-1.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}"/${P}-1
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+# doxygen is always needed for man pages, but USE=doc controls installing docs themselves
+# (not man pages)
+IUSE="doc ncurses numa"
+
+RDEPEND="
+	dev-libs/libyaml
+	dev-libs/openssl:=
+	>=net-libs/libpcap-0.8
+	net-libs/wandio
+	ncurses? ( sys-libs/ncurses:= )
+	numa? ( sys-process/numactl )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	app-doc/doxygen[dot]
+	sys-devel/flex
+	virtual/os-headers
+	virtual/pkgconfig
+	virtual/yacc
+"
+
+src_prepare() {
+	default
+
+	eautoreconf
+
+	# Comment out FILE_PATTERNS definition (bug #706230)
+	if has_version ~app-doc/doxygen-1.8.16; then
+		sed -i -e '/^FILE_PATTERNS/s|^|#|g' docs/${PN}.doxygen.in || die
+	fi
+
+	# Update doxygen configuration
+	doxygen -u docs/libtrace.doxygen.in || die
+}
+
+src_configure() {
+	econf \
+		$(use_with ncurses) \
+		$(use_with numa) \
+		--with-man \
+		--without-dpdk
+}
+
+src_install() {
+	default
+
+	if use doc ; then
+		docinto html
+		dodoc -r docs/doxygen/html
+	fi
+
+	find "${ED}" -name "*.la" -delete || die
+}