1 files changed, 60 insertions, 0 deletions
diff --git a/net-libs/libtrace/libtrace-4.0.9_p1.ebuild b/net-libs/libtrace/libtrace-4.0.9_p1.ebuild
new file mode 100644
index 000000000000..1c1a3c50f73e
--- /dev/null
+++ b/net-libs/libtrace/libtrace-4.0.9_p1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools
+
+DESCRIPTION="A library and tools for trace processing"
+HOMEPAGE="https://research.wand.net.nz/software/libtrace.php"
+SRC_URI="https://github.com/${PN^}Team/${PN}/archive//${PV/_p/-}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc ncurses numa static-libs"
+
+RDEPEND="
+	>=net-libs/libpcap-0.8
+	dev-libs/libyaml
+	dev-libs/openssl:0=
+	net-libs/wandio
+	ncurses? ( sys-libs/ncurses:0= )
+	numa? ( sys-process/numactl )
+"
+DEPEND="
+	${RDEPEND}
+	app-doc/doxygen
+	sys-devel/flex
+	virtual/pkgconfig
+	virtual/yacc
+"
+PATCHES=(
+		"${FILESDIR}"/${PN}-3.0.20-autoconf-1.13.patch
+		"${FILESDIR}"/${PN}-4.0.0-no-examples.patch
+		"${FILESDIR}"/${PN}-4.0.0-with-numa.patch
+		"${FILESDIR}"/${PN}-4.0.9_p1-tinfo.patch
+)
+S=${WORKDIR}/${P/_p/-}
+
+src_prepare() {
+cp -av configure.in{,.orig} || die
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		$(use_with ncurses) \
+		$(use_with numa) \
+		--with-man
+}
+
+src_install() {
+	default
+
+	use doc && dodoc -r docs/doxygen/html
+
+	find "${D}" -name "*.la" -delete || die
+}