summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'net-libs/xrootd/xrootd-5.1.1-r1.ebuild')
-rw-r--r--net-libs/xrootd/xrootd-5.1.1-r1.ebuild117
1 files changed, 0 insertions, 117 deletions
diff --git a/net-libs/xrootd/xrootd-5.1.1-r1.ebuild b/net-libs/xrootd/xrootd-5.1.1-r1.ebuild
deleted file mode 100644
index b997510b59a..00000000000
--- a/net-libs/xrootd/xrootd-5.1.1-r1.ebuild
+++ /dev/null
@@ -1,117 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{7..9} )
-
-# Upstream does not support the building of Python bindings
-# via CMake for more than one implementation at a time.
-inherit cmake python-single-r1
-
-DESCRIPTION="Extended ROOT remote file server"
-HOMEPAGE="http://xrootd.org/"
-SRC_URI="http://xrootd.org/download/v${PV}/${P}.tar.gz"
-
-LICENSE="LGPL-3"
-SLOT="0"
-KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
-IUSE="doc examples fuse http kerberos python readline ssl test"
-RESTRICT="!test? ( test )"
-
-CDEPEND="acct-group/xrootd
- acct-user/xrootd
- sys-libs/zlib
- virtual/libcrypt:=
- fuse? ( sys-fs/fuse:= )
- kerberos? ( virtual/krb5 )
- python? ( ${PYTHON_DEPS} )
- readline? ( sys-libs/readline:0= )
- ssl? ( <dev-libs/openssl-3.0.0:0= )
-"
-DEPEND="${CDEPEND}"
-BDEPEND="
- doc? (
- app-doc/doxygen[dot]
- python? ( dev-python/sphinx )
- )
- test? ( dev-util/cppunit )
-"
-RDEPEND="${CDEPEND}
- dev-lang/perl
-"
-REQUIRED_USE="
- http? ( kerberos ssl )
- python? ( ${PYTHON_REQUIRED_USE} )
-"
-
-PATCHES=( "${FILESDIR}"/xrootd-4.8.3-crc32.patch )
-
-# xrootd plugins are not intended to be linked with,
-# they are to be loaded at runtime by xrootd,
-# see https://github.com/xrootd/xrootd/issues/447
-QA_SONAME="/usr/lib.*/libXrd.*-$(ver_cut 1)\.so
- /usr/lib.*/libXrdClTests\.so"
-
-pkg_setup() {
- use python && python_setup
-}
-
-src_configure() {
- local mycmakeargs=(
- -DENABLE_CRYPTO=$(usex ssl)
- -DENABLE_FUSE=$(usex fuse)
- -DENABLE_HTTP=$(usex http)
- -DENABLE_KRB5=$(usex kerberos)
- -DENABLE_PYTHON=$(usex python)
- -DENABLE_READLINE=$(usex readline)
- -DENABLE_TESTS=$(usex test)
- )
- cmake_src_configure
-}
-
-src_compile() {
- cmake_src_compile
- if use doc; then
- doxygen Doxyfile || die
- if use python; then
- emake -C bindings/python/docs html
- fi
- fi
-}
-
-src_install() {
- use doc && HTML_DOCS=( doxydoc/html/. )
- dodoc docs/ReleaseNotes.txt
- cmake_src_install
- find "${D}" \( -iname '*.md5' -o -iname '*.map' \) -delete || die
-
- # base configs
- insinto /etc/xrootd
- doins packaging/common/*.cfg
-
- fowners root:xrootd /etc/xrootd
- keepdir /var/log/xrootd
- fowners xrootd:xrootd /var/log/xrootd
-
- local i
- for i in cmsd frm_purged frm_xfrd xrootd; do
- newinitd "${FILESDIR}"/${i}.initd ${i}
- done
- # all daemons MUST use single master config file
- newconfd "${FILESDIR}"/xrootd.confd xrootd
-
- if use python; then
- python_optimize "${D}/$(python_get_sitedir)"
-
- if use doc; then
- docinto python
- docompress -x "/usr/share/doc/${PF}/python/html"
- dodoc -r bindings/python/docs/build/html
- fi
- if use examples; then
- docinto python
- dodoc -r bindings/python/examples
- fi
- fi
-}