1 files changed, 54 insertions, 0 deletions
diff --git a/net-mail/onionrouter/onionrouter-0.5.2.ebuild b/net-mail/onionrouter/onionrouter-0.5.2.ebuild
new file mode 100644
index 000000000000..f8875c8a7400
--- /dev/null
+++ b/net-mail/onionrouter/onionrouter-0.5.2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1 systemd
+
+DESCRIPTION=".onion discovery via SRV DNS lookups for use with postfix"
+HOMEPAGE="https://pypi.org/project/onionrouter/ https://github.com/ehloonion/onionrouter/"
+SRC_URI="https://pypi.io/packages/source/${PN::1}/${PN}/${P}.tar.gz"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="$(python_gen_cond_dep '
+	dev-python/dnspython[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+')"
+BDEPEND="$(python_gen_cond_dep '
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/wheel[${PYTHON_USEDEP}]
+	)
+')"
+
+PATCHES=(
+	"${FILESDIR}/${P}-entrypoint.patch"
+	"${FILESDIR}/${P}-python3.patch"
+	"${FILESDIR}/${P}-pyyaml-version.patch"
+	"${FILESDIR}/${P}-newline.patch"
+)
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# https://github.com/ehloonion/onionrouter/pull/15
+	cp "${FILESDIR}/conftest.py" "${S}" || die
+
+	distutils-r1_src_prepare
+}
+
+src_install() {
+	distutils-r1_src_install
+	systemd_dounit "${FILESDIR}/${PN}.service"
+	insinto /etc/onionrouter
+	doins "${S}/onionrouter/configs/onionrouter.ini"
+}