1 files changed, 71 insertions, 0 deletions
diff --git a/net-misc/gns3-server/gns3-server-2.2.44.1.ebuild b/net-misc/gns3-server/gns3-server-2.2.44.1.ebuild
new file mode 100644
index 000000000000..ec1573e4269f
--- /dev/null
+++ b/net-misc/gns3-server/gns3-server-2.2.44.1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..12} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1 optfeature systemd
+
+DESCRIPTION="GNS3 server to asynchronously manage emulators"
+HOMEPAGE="https://www.gns3.com https://github.com/GNS3/gns3-server"
+SRC_URI="https://github.com/GNS3/gns3-server/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	acct-group/gns3
+	acct-user/gns3
+	app-emulation/dynamips
+	>=dev-python/aiofiles-23.2.1[${PYTHON_USEDEP}]
+	>=dev-python/aiohttp-3.8.5[${PYTHON_USEDEP}]
+	>=dev-python/aiohttp-cors-0.7.0[${PYTHON_USEDEP}]
+	>=dev-python/async-timeout-4.0.2[${PYTHON_USEDEP}]
+	>=dev-python/distro-1.8.0[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.1.2[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-4.17.3[${PYTHON_USEDEP}]
+	>=dev-python/psutil-5.9.6[${PYTHON_USEDEP}]
+	>=dev-python/py-cpuinfo-9.0.0[${PYTHON_USEDEP}]
+	>=dev-python/sentry-sdk-1.34.0[${PYTHON_USEDEP}]
+	net-misc/ubridge
+	sys-apps/busybox[static]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-aiohttp[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	default
+
+	# newer python packages are fine
+	sed -i -e 's/[<>=].*//' requirements.txt || die
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	systemd_dounit init/gns3.service.systemd
+	newinitd init/gns3.service.openrc gns3server
+
+	rm "${D}$(python_get_sitedir)/gns3server/compute/docker/resources/bin/busybox" || die
+	ln -s /bin/busybox "${D}$(python_get_sitedir)/gns3server/compute/docker/resources/bin/busybox" || die
+}
+
+pkg_postinst() {
+	elog "net-misc/gns3-server has several optional packages that must be merged manually for additional functionality."
+	elog ""
+	optfeature "QEMU Support" "app-emulation/qemu"
+	optfeature "Virtualbox Support" "app-emulation/virtualbox"
+	optfeature "Docker Support" "app-containers/docker"
+	optfeature "Wireshark Support" "net-analyzer/wireshark"
+	elog ""
+	elog "The following packages are currently unsupported:"
+	elog "iouyap and vpcs"
+}