1 files changed, 47 insertions, 0 deletions
diff --git a/net-misc/yandex-disk/yandex-disk-0.1.5.940_p1.ebuild b/net-misc/yandex-disk/yandex-disk-0.1.5.940_p1.ebuild
new file mode 100644
index 000000000000..c83d92d2b2e6
--- /dev/null
+++ b/net-misc/yandex-disk/yandex-disk-0.1.5.940_p1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit bash-completion-r1 eutils rpm
+
+MY_P="${PN}-${PV/_p/-}"
+
+DESCRIPTION="CLI to access Yandex Disk file storage service"
+HOMEPAGE="https://disk.yandex.ru"
+SRC_URI="
+	amd64? ( http://repo.yandex.ru/yandex-disk/rpm/stable/x86_64/${MY_P}.fedora.x86_64.rpm )
+	x86? ( http://repo.yandex.ru/yandex-disk/rpm/stable/i386/${MY_P}.fedora.i386.rpm )
+"
+
+LICENSE="YDSLA"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+
+DEPEND=""
+RDEPEND="sys-libs/zlib"
+
+S="${WORKDIR}"
+
+QA_PREBUILT="opt/bin/yandex-disk"
+
+src_prepare() {
+	# bug #526312
+	sed -i \
+		-e '/have /d' \
+		-e 's/+o nospace/-o nospace/' \
+		-e '/^complete/s/-X //' \
+		etc/bash_completion.d/yandex-disk-completion.bash || die
+
+	epatch_user
+}
+
+src_install() {
+	exeinto /opt/bin
+	doexe usr/bin/yandex-disk
+	newbashcomp etc/bash_completion.d/yandex-disk-completion.bash "${PN}"
+	doman usr/share/man/man1/*.gz
+	insinto /usr/share
+	doins -r usr/share/locale
+}