1 files changed, 54 insertions, 0 deletions
diff --git a/sci-libs/cln/cln-1.3.6.ebuild b/sci-libs/cln/cln-1.3.6.ebuild
new file mode 100644
index 000000000000..6d68f1bf39d9
--- /dev/null
+++ b/sci-libs/cln/cln-1.3.6.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic
+
+DESCRIPTION="Class library (C++) for numbers"
+HOMEPAGE="https://www.ginac.de/CLN/"
+SRC_URI="https://www.ginac.de/CLN/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="1"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples static-libs"
+
+RDEPEND="dev-libs/gmp:0="
+DEPEND="${RDEPEND}
+	doc? ( virtual/latex-base )"
+
+pkg_setup() {
+	use sparc && append-cppflags -DNO_ASM
+	use hppa && append-cppflags -DNO_ASM
+	use arm && append-cppflags -DNO_ASM
+}
+
+src_prepare() {
+	default
+	# avoid building examples
+	# do it in Makefile.in to avoid time consuming eautoreconf
+	sed -i \
+		-e '/^SUBDIRS.*=/s/examples doc benchmarks/doc/' \
+		Makefile.in || die
+}
+
+src_compile() {
+	default
+	if use doc; then
+		cd "${BUILD_DIR}"
+		export VARTEXFONTS="${T}/fonts"
+		emake html pdf
+		DOCS=("${BUILD_DIR}/doc/cln.pdf")
+		HTML_DOCS=("${BUILD_DIR}/doc/")
+	fi
+}
+
+src_install () {
+	default
+	if use examples; then
+		docompress -x /usr/share/doc/${PF}/examples
+		insinto /usr/share/doc/${PF}/examples
+		doins examples/*.cc
+	fi
+}